ld/configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 AC_PREREG(2.13)
   4 AC_INIT(ldmain.c)
   5
   6 AC_CANONICAL_SYSTEM
   7
   8 AM_INIT_AUTOMAKE(ld, 2.9.5)
   9
  10 AM_PROG_LIBTOOL
  11
  12 AC_ARG_ENABLE(targets,
  13 [  --enable-targets        alternative target configurations],
  14 [case "${enableval}" in
  15   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  16             ;;
  17   no)       enable_targets= ;;
  18   *)        enable_targets=$enableval ;;
  19 esac])dnl
  20 AC_ARG_ENABLE(64-bit-bfd,
  21 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  22 [case "${enableval}" in
  23   yes)  want64=true  ;;
  24   no)   want64=false ;;
  25   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  26 esac],[want64=false])dnl
  27
  28 AM_CONFIG_HEADER(config.h:config.in)
  29
  30 if test -z "$target" ; then
  31     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  32 fi
  33 if test -z "$host" ; then
  34     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
  35 fi
  36
  37 # host-specific stuff:
  38
  39 AC_PROG_CC
  40 AC_PROG_INSTALL
  41
  42 ALL_LINGUAS=
  43 CY_GNU_GETTEXT
  44
  45 AC_EXEEXT
  46
  47 AC_PROG_YACC
  48 AM_PROG_LEX
  49
  50 AM_MAINTAINER_MODE
  51
  52 . ${srcdir}/configure.host
  53
  54 AC_SUBST(HDEFINES)
  55 AC_SUBST(HOSTING_CRT0)
  56 AC_SUBST(HOSTING_LIBS)
  57 AC_SUBST(NATIVE_LIB_DIRS)
  58
  59 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h)
  60 AC_CHECK_FUNCS(sbrk)
  61 AC_HEADER_DIRENT
  62
  63 BFD_BINARY_FOPEN
  64
  65 BFD_NEED_DECLARATION(strstr)
  66 BFD_NEED_DECLARATION(free)
  67 BFD_NEED_DECLARATION(sbrk)
  68 BFD_NEED_DECLARATION(getenv)
  69 BFD_NEED_DECLARATION(environ)
  70
  71 # target-specific stuff:
  72
  73 all_targets=
  74 EMUL=
  75 all_emuls=
  76 all_emul_extras=
  77 all_libpath=
  78
  79 dnl We need to get an arbitrary number of tdir definitions into
  80 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
  81 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
  82 dnl file.
  83 rm -f tdirs
  84
  85 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
  86 do
  87   if test "$targ_alias" = "all"; then
  88     all_targets=true
  89   else
  90     # Canonicalize the secondary target names.
  91     result=`${CONFIG_SHELL-/bin/sh} $ac_config_sub $targ_alias 2>/dev/null`
  92     if test -n "$result"; then
  93         targ=$result
  94     else
  95         targ=$targ_alias
  96     fi
  97
  98     . ${srcdir}/configure.tgt
  99
 100     if test "$targ" = "$target"; then
 101       EMUL=$targ_emul
 102     fi
 103
 104     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 105         case " $all_emuls " in
 106         *" e${i}.o "*) ;;
 107         *)
 108           all_emuls="$all_emuls e${i}.o"
 109           eval result=\$tdir_$i
 110           test -z "$result" && result=$targ_alias
 111           echo tdir_$i=$result >> tdirs
 112           ;;
 113         esac
 114     done
 115
 116     for i in $targ_emul $targ_extra_libpath; do
 117         case " $all_libpath " in
 118         *" ${i} "*) ;;
 119         *)
 120           if test -z "$all_libpath"; then
 121             all_libpath=${i}
 122           else
 123             all_libpath="$all_libpath ${i}"
 124           fi
 125           ;;
 126         esac
 127     done
 128
 129     for i in $targ_extra_ofiles; do
 130         case " $all_emul_extras " in
 131         *" ${i} "*) ;;
 132         *)
 133           all_emul_extras="$all_emul_extras ${i}"
 134           ;;
 135         esac
 136     done
 137   fi
 138 done
 139
 140 AC_SUBST(EMUL)
 141
 142 TDIRS=tdirs
 143 AC_SUBST_FILE(TDIRS)
 144
 145 dnl FIXME: We will build a 64 bit BFD for a 64 bit host or a 64 bit
 146 dnl target, and in those cases we should also build the 64 bit
 147 dnl emulations.
 148 if test x${all_targets} = xtrue; then
 149   if test x${want64} = xtrue; then
 150     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 151   else
 152     EMULATION_OFILES='$(ALL_EMULATIONS)'
 153   fi
 154   EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 155 else
 156   EMULATION_OFILES=$all_emuls
 157   EMUL_EXTRA_OFILES=$all_emul_extras
 158 fi
 159 AC_SUBST(EMULATION_OFILES)
 160 AC_SUBST(EMUL_EXTRA_OFILES)
 161
 162 EMULATION_LIBPATH=$all_libpath
 163 AC_SUBST(EMULATION_LIBPATH)
 164
 165 if test x${enable_static} = xno; then
 166   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 167 else
 168   TESTBFDLIB="../bfd/.libs/libbfd.a"
 169 fi
 170 AC_SUBST(TESTBFDLIB)
 171
 172 AC_OUTPUT(Makefile po/Makefile.in:po/Make-in,
 173 [sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile])