ld/ldlex.l

   1 %option nounput
   2
   3 %{
   4
   5 /* Copyright (C) 1991-2016 Free Software Foundation, Inc.
   6    Written by Steve Chamberlain of Cygnus Support.
   7
   8    This file is part of the GNU Binutils.
   9
  10    This program is free software; you can redistribute it and/or modify
  11    it under the terms of the GNU General Public License as published by
  12    the Free Software Foundation; either version 3 of the License, or
  13    (at your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful,
  16    but WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18    GNU General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; if not, write to the Free Software
  22    Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston,
  23    MA 02110-1301, USA.  */
  24
  25 #include "bfd.h"
  26 #include "safe-ctype.h"
  27 #include "bfdlink.h"
  28 #include "ld.h"
  29 #include "ldmisc.h"
  30 #include "ldexp.h"
  31 #include "ldlang.h"
  32 #include <ldgram.h>
  33 #include "ldfile.h"
  34 #include "ldlex.h"
  35 #include "ldmain.h"
  36 #include "libiberty.h"
  37
  38 /* The type of top-level parser input.
  39    yylex and yyparse (indirectly) both check this.  */
  40 input_type parser_input;
  41
  42 /* Line number in the current input file.  */
  43 unsigned int lineno;
  44
  45 /* The string we are currently lexing, or NULL if we are reading a
  46    file.  */
  47 const char *lex_string = NULL;
  48
  49 /* Support for flex reading from more than one input file (stream).
  50    `include_stack' is flex's input state for each open file;
  51    `file_name_stack' is the file names.  `lineno_stack' is the current
  52    line numbers.
  53
  54    If `include_stack_ptr' is 0, we haven't started reading anything yet.
  55    Otherwise, stack elements 0 through `include_stack_ptr - 1' are valid.  */
  56
  57 #undef YY_INPUT
  58 #define YY_INPUT(buf,result,max_size) result = yy_input (buf, max_size)
  59
  60 #ifndef YY_NO_UNPUT
  61 #define YY_NO_UNPUT
  62 #endif
  63
  64 #define MAX_INCLUDE_DEPTH 10
  65 static YY_BUFFER_STATE include_stack[MAX_INCLUDE_DEPTH];
  66 static const char *file_name_stack[MAX_INCLUDE_DEPTH];
  67 static unsigned int lineno_stack[MAX_INCLUDE_DEPTH];
  68 static unsigned int sysrooted_stack[MAX_INCLUDE_DEPTH];
  69 static unsigned int include_stack_ptr = 0;
  70 static int vers_node_nesting = 0;
  71
  72 static int yy_input (char *, int);
  73 static void comment (void);
  74 static void lex_warn_invalid (char *where, char *what);
  75
  76 /* STATES
  77         EXPRESSION      definitely in an expression
  78         SCRIPT          definitely in a script
  79         INPUTLIST       definitely in a script, a filename-list
  80         BOTH            either EXPRESSION or SCRIPT
  81         DEFSYMEXP       in an argument to -defsym
  82         MRI             in an MRI script
  83         VERS_START      starting a Sun style mapfile
  84         VERS_SCRIPT     a Sun style mapfile
  85         VERS_NODE       a node within a Sun style mapfile
  86 */
  87 #define RTOKEN(x)  {  yylval.token = x; return x; }
  88
  89 /* Some versions of flex want this.  */
  90 #ifndef yywrap
  91 int yywrap (void) { return 1; }
  92 #endif
  93 %}
  94
  95 %a 4000
  96 %o 5000
  97
  98 CMDFILENAMECHAR   [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\-\~]
  99 CMDFILENAMECHAR1  [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\~]
 100 FILENAMECHAR1   [_a-zA-Z\/\.\\\$\_\~]
 101 SYMBOLCHARN     [_a-zA-Z\/\.\\\$\_\~0-9]
 102 FILENAMECHAR    [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~]
 103 WILDCHAR        [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~\?\*\^\!]
 104 WHITE           [ \t\n\r]+
 105
 106 NOCFILENAMECHAR [_a-zA-Z0-9\/\.\-\_\+\$\:\[\]\\\~]
 107
 108 V_TAG [.$_a-zA-Z][._a-zA-Z0-9]*
 109 V_IDENTIFIER [*?.$_a-zA-Z\[\]\-\!\^\\]([*?.$_a-zA-Z0-9\[\]\-\!\^\\]|::)*
 110
 111 %s SCRIPT
 112 %s INPUTLIST
 113 %s EXPRESSION
 114 %s BOTH
 115 %s DEFSYMEXP
 116 %s MRI
 117 %s VERS_START
 118 %s VERS_SCRIPT
 119 %s VERS_NODE
 120 %%
 121
 122   if (parser_input != input_selected)
 123     {
 124       /* The first token of the input determines the initial parser state.  */
 125       input_type t = parser_input;
 126       parser_input = input_selected;
 127       switch (t)
 128         {
 129         case input_script: return INPUT_SCRIPT; break;
 130         case input_mri_script: return INPUT_MRI_SCRIPT; break;
 131         case input_version_script: return INPUT_VERSION_SCRIPT; break;
 132         case input_dynamic_list: return INPUT_DYNAMIC_LIST; break;
 133         case input_defsym: return INPUT_DEFSYM; break;
 134         default: abort ();
 135         }
 136     }
 137
 138 <BOTH,SCRIPT,EXPRESSION,VERS_START,VERS_NODE,VERS_SCRIPT,INPUTLIST>"/*" { comment (); }
 139
 140
 141 <DEFSYMEXP>"-"                  { RTOKEN('-');}
 142 <DEFSYMEXP>"+"                  { RTOKEN('+');}
 143 <DEFSYMEXP>{FILENAMECHAR1}{SYMBOLCHARN}*   { yylval.name = xstrdup (yytext); return NAME; }
 144 <DEFSYMEXP>"="                  { RTOKEN('='); }
 145
 146 <MRI,EXPRESSION>"$"([0-9A-Fa-f])+ {
 147                                 yylval.integer = bfd_scan_vma (yytext + 1, 0, 16);
 148                                 yylval.bigint.str = NULL;
 149                                 return INT;
 150                         }
 151
 152 <MRI,EXPRESSION>([0-9A-Fa-f])+(H|h|X|x|B|b|O|o|D|d) {
 153                                    int ibase ;
 154                                    switch (yytext[yyleng - 1]) {
 155                                     case 'X':
 156                                     case 'x':
 157                                     case 'H':
 158                                     case 'h':
 159                                      ibase = 16;
 160                                      break;
 161                                     case 'O':
 162                                     case 'o':
 163                                      ibase = 8;
 164                                      break;
 165                                     case 'B':
 166                                     case 'b':
 167                                      ibase = 2;
 168                                      break;
 169                                     default:
 170                                      ibase = 10;
 171                                    }
 172                                    yylval.integer = bfd_scan_vma (yytext, 0,
 173                                                                   ibase);
 174                                    yylval.bigint.str = NULL;
 175                                    return INT;
 176                                  }
 177 <SCRIPT,DEFSYMEXP,MRI,BOTH,EXPRESSION>((("$"|0[xX])([0-9A-Fa-f])+)|(([0-9])+))(M|K|m|k)? {
 178                                   char *s = yytext;
 179                                   int ibase = 0;
 180
 181                                   if (*s == '$')
 182                                     {
 183                                       ++s;
 184                                       ibase = 16;
 185                                     }
 186                                   yylval.integer = bfd_scan_vma (s, 0, ibase);
 187                                   yylval.bigint.str = NULL;
 188                                   if (yytext[yyleng - 1] == 'M'
 189                                       || yytext[yyleng - 1] == 'm')
 190                                     {
 191                                       yylval.integer *= 1024 * 1024;
 192                                     }
 193                                   else if (yytext[yyleng - 1] == 'K'
 194                                       || yytext[yyleng - 1]=='k')
 195                                     {
 196                                       yylval.integer *= 1024;
 197                                     }
 198                                   else if (yytext[0] == '0'
 199                                            && (yytext[1] == 'x'
 200                                                || yytext[1] == 'X'))
 201                                     {
 202                                       yylval.bigint.str = xstrdup (yytext + 2);
 203                                     }
 204                                   return INT;
 205                                 }
 206 <BOTH,SCRIPT,EXPRESSION,MRI>"]"         { RTOKEN(']');}
 207 <BOTH,SCRIPT,EXPRESSION,MRI>"["         { RTOKEN('[');}
 208 <BOTH,SCRIPT,EXPRESSION,MRI>"<<="       { RTOKEN(LSHIFTEQ);}
 209 <BOTH,SCRIPT,EXPRESSION,MRI>">>="       { RTOKEN(RSHIFTEQ);}
 210 <BOTH,SCRIPT,EXPRESSION,MRI>"||"        { RTOKEN(OROR);}
 211 <BOTH,SCRIPT,EXPRESSION,MRI>"=="        { RTOKEN(EQ);}
 212 <BOTH,SCRIPT,EXPRESSION,MRI>"!="        { RTOKEN(NE);}
 213 <BOTH,SCRIPT,EXPRESSION,MRI>">="        { RTOKEN(GE);}
 214 <BOTH,SCRIPT,EXPRESSION,MRI>"<="        { RTOKEN(LE);}
 215 <BOTH,SCRIPT,EXPRESSION,MRI>"<<"        { RTOKEN(LSHIFT);}
 216 <BOTH,SCRIPT,EXPRESSION,MRI>">>"        { RTOKEN(RSHIFT);}
 217 <BOTH,SCRIPT,EXPRESSION,MRI>"+="        { RTOKEN(PLUSEQ);}
 218 <BOTH,SCRIPT,EXPRESSION,MRI>"-="        { RTOKEN(MINUSEQ);}
 219 <BOTH,SCRIPT,EXPRESSION,MRI>"*="        { RTOKEN(MULTEQ);}
 220 <BOTH,SCRIPT,EXPRESSION,MRI>"/="        { RTOKEN(DIVEQ);}
 221 <BOTH,SCRIPT,EXPRESSION,MRI>"&="        { RTOKEN(ANDEQ);}
 222 <BOTH,SCRIPT,EXPRESSION,MRI>"|="        { RTOKEN(OREQ);}
 223 <BOTH,SCRIPT,EXPRESSION,MRI>"&&"        { RTOKEN(ANDAND);}
 224 <BOTH,SCRIPT,EXPRESSION,MRI>">"         { RTOKEN('>');}
 225 <BOTH,SCRIPT,EXPRESSION,MRI,INPUTLIST>","               { RTOKEN(',');}
 226 <BOTH,SCRIPT,EXPRESSION,MRI>"&"         { RTOKEN('&');}
 227 <BOTH,SCRIPT,EXPRESSION,MRI>"|"         { RTOKEN('|');}
 228 <BOTH,SCRIPT,EXPRESSION,MRI>"~"         { RTOKEN('~');}
 229 <BOTH,SCRIPT,EXPRESSION,MRI>"!"         { RTOKEN('!');}
 230 <BOTH,SCRIPT,EXPRESSION,MRI>"?"         { RTOKEN('?');}
 231 <BOTH,SCRIPT,EXPRESSION,MRI>"*"         { RTOKEN('*');}
 232 <BOTH,SCRIPT,EXPRESSION,MRI>"+"         { RTOKEN('+');}
 233 <BOTH,SCRIPT,EXPRESSION,MRI>"-"         { RTOKEN('-');}
 234 <BOTH,SCRIPT,EXPRESSION,MRI>"/"         { RTOKEN('/');}
 235 <BOTH,SCRIPT,EXPRESSION,MRI>"%"         { RTOKEN('%');}
 236 <BOTH,SCRIPT,EXPRESSION,MRI>"<"         { RTOKEN('<');}
 237 <BOTH,SCRIPT,EXPRESSION,MRI>"="         { RTOKEN('=');}
 238 <BOTH,SCRIPT,EXPRESSION,MRI>"}"         { RTOKEN('}') ; }
 239 <BOTH,SCRIPT,EXPRESSION,MRI>"{"         { RTOKEN('{'); }
 240 <BOTH,SCRIPT,EXPRESSION,MRI,INPUTLIST>")"               { RTOKEN(')');}
 241 <BOTH,SCRIPT,EXPRESSION,MRI,INPUTLIST>"("               { RTOKEN('(');}
 242 <BOTH,SCRIPT,EXPRESSION,MRI>":"         { RTOKEN(':'); }
 243 <BOTH,SCRIPT,EXPRESSION,MRI>";"         { RTOKEN(';');}
 244 <BOTH,SCRIPT>"MEMORY"                   { RTOKEN(MEMORY);}
 245 <BOTH,SCRIPT>"REGION_ALIAS"             { RTOKEN(REGION_ALIAS);}
 246 <BOTH,SCRIPT>"LD_FEATURE"               { RTOKEN(LD_FEATURE);}
 247 <BOTH,SCRIPT,EXPRESSION>"ORIGIN"        { RTOKEN(ORIGIN);}
 248 <BOTH,SCRIPT>"VERSION"                  { RTOKEN(VERSIONK);}
 249 <EXPRESSION,BOTH,SCRIPT>"BLOCK"         { RTOKEN(BLOCK);}
 250 <EXPRESSION,BOTH,SCRIPT>"BIND"          { RTOKEN(BIND);}
 251 <BOTH,SCRIPT,EXPRESSION>"LENGTH"        { RTOKEN(LENGTH);}
 252 <EXPRESSION,BOTH,SCRIPT>"ALIGN"         { RTOKEN(ALIGN_K);}
 253 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_ALIGN"    { RTOKEN(DATA_SEGMENT_ALIGN);}
 254 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_RELRO_END"        { RTOKEN(DATA_SEGMENT_RELRO_END);}
 255 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_END"      { RTOKEN(DATA_SEGMENT_END);}
 256 <EXPRESSION,BOTH,SCRIPT>"ADDR"          { RTOKEN(ADDR);}
 257 <EXPRESSION,BOTH,SCRIPT>"LOADADDR"      { RTOKEN(LOADADDR);}
 258 <EXPRESSION,BOTH,SCRIPT>"ALIGNOF"       { RTOKEN(ALIGNOF); }
 259 <EXPRESSION,BOTH>"MAX"                  { RTOKEN(MAX_K); }
 260 <EXPRESSION,BOTH>"MIN"                  { RTOKEN(MIN_K); }
 261 <EXPRESSION,BOTH>"LOG2CEIL"             { RTOKEN(LOG2CEIL); }
 262 <EXPRESSION,BOTH,SCRIPT>"ASSERT"        { RTOKEN(ASSERT_K); }
 263 <BOTH,SCRIPT>"ENTRY"                    { RTOKEN(ENTRY);}
 264 <BOTH,SCRIPT,MRI>"EXTERN"               { RTOKEN(EXTERN);}
 265 <EXPRESSION,BOTH,SCRIPT>"NEXT"          { RTOKEN(NEXT);}
 266 <EXPRESSION,BOTH,SCRIPT>"sizeof_headers"        { RTOKEN(SIZEOF_HEADERS);}
 267 <EXPRESSION,BOTH,SCRIPT>"SIZEOF_HEADERS"        { RTOKEN(SIZEOF_HEADERS);}
 268 <EXPRESSION,BOTH,SCRIPT>"SEGMENT_START" { RTOKEN(SEGMENT_START);}
 269 <BOTH,SCRIPT>"MAP"                      { RTOKEN(MAP);}
 270 <EXPRESSION,BOTH,SCRIPT>"SIZEOF"        { RTOKEN(SIZEOF);}
 271 <BOTH,SCRIPT>"TARGET"                   { RTOKEN(TARGET_K);}
 272 <BOTH,SCRIPT>"SEARCH_DIR"               { RTOKEN(SEARCH_DIR);}
 273 <BOTH,SCRIPT>"OUTPUT"                   { RTOKEN(OUTPUT);}
 274 <BOTH,SCRIPT>"INPUT"                    { RTOKEN(INPUT);}
 275 <EXPRESSION,BOTH,SCRIPT>"GROUP"         { RTOKEN(GROUP);}
 276 <EXPRESSION,BOTH,SCRIPT,INPUTLIST>"AS_NEEDED"   { RTOKEN(AS_NEEDED);}
 277 <EXPRESSION,BOTH,SCRIPT>"DEFINED"       { RTOKEN(DEFINED);}
 278 <BOTH,SCRIPT>"CREATE_OBJECT_SYMBOLS"    { RTOKEN(CREATE_OBJECT_SYMBOLS);}
 279 <BOTH,SCRIPT>"CONSTRUCTORS"             { RTOKEN( CONSTRUCTORS);}
 280 <BOTH,SCRIPT>"FORCE_COMMON_ALLOCATION"  { RTOKEN(FORCE_COMMON_ALLOCATION);}
 281 <BOTH,SCRIPT>"INHIBIT_COMMON_ALLOCATION" { RTOKEN(INHIBIT_COMMON_ALLOCATION);}
 282 <BOTH,SCRIPT>"SECTIONS"                 { RTOKEN(SECTIONS);}
 283 <BOTH,SCRIPT>"INSERT"                   { RTOKEN(INSERT_K);}
 284 <BOTH,SCRIPT>"AFTER"                    { RTOKEN(AFTER);}
 285 <BOTH,SCRIPT>"BEFORE"                   { RTOKEN(BEFORE);}
 286 <BOTH,SCRIPT>"FILL"                     { RTOKEN(FILL);}
 287 <BOTH,SCRIPT>"STARTUP"                  { RTOKEN(STARTUP);}
 288 <BOTH,SCRIPT>"OUTPUT_FORMAT"            { RTOKEN(OUTPUT_FORMAT);}
 289 <BOTH,SCRIPT>"OUTPUT_ARCH"              { RTOKEN( OUTPUT_ARCH);}
 290 <BOTH,SCRIPT>"HLL"                      { RTOKEN(HLL);}
 291 <BOTH,SCRIPT>"SYSLIB"                   { RTOKEN(SYSLIB);}
 292 <BOTH,SCRIPT>"FLOAT"                    { RTOKEN(FLOAT);}
 293 <BOTH,SCRIPT>"QUAD"                     { RTOKEN( QUAD);}
 294 <BOTH,SCRIPT>"SQUAD"                    { RTOKEN( SQUAD);}
 295 <BOTH,SCRIPT>"LONG"                     { RTOKEN( LONG);}
 296 <BOTH,SCRIPT>"SHORT"                    { RTOKEN( SHORT);}
 297 <BOTH,SCRIPT>"BYTE"                     { RTOKEN( BYTE);}
 298 <BOTH,SCRIPT>"NOFLOAT"                  { RTOKEN(NOFLOAT);}
 299 <EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS"   { RTOKEN(NOCROSSREFS);}
 300 <EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS_TO" { RTOKEN(NOCROSSREFS_TO);}
 301 <BOTH,SCRIPT>"OVERLAY"                  { RTOKEN(OVERLAY); }
 302 <BOTH,SCRIPT>"SORT_BY_NAME"             { RTOKEN(SORT_BY_NAME); }
 303 <BOTH,SCRIPT>"SORT_BY_ALIGNMENT"        { RTOKEN(SORT_BY_ALIGNMENT); }
 304 <BOTH,SCRIPT>"SORT"                     { RTOKEN(SORT_BY_NAME); }
 305 <BOTH,SCRIPT>"SORT_BY_INIT_PRIORITY"    { RTOKEN(SORT_BY_INIT_PRIORITY); }
 306 <BOTH,SCRIPT>"SORT_NONE"                { RTOKEN(SORT_NONE); }
 307 <EXPRESSION,BOTH,SCRIPT>"NOLOAD"        { RTOKEN(NOLOAD);}
 308 <EXPRESSION,BOTH,SCRIPT>"DSECT"         { RTOKEN(DSECT);}
 309 <EXPRESSION,BOTH,SCRIPT>"COPY"          { RTOKEN(COPY);}
 310 <EXPRESSION,BOTH,SCRIPT>"INFO"          { RTOKEN(INFO);}
 311 <EXPRESSION,BOTH,SCRIPT>"OVERLAY"       { RTOKEN(OVERLAY);}
 312 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RO"    { RTOKEN(ONLY_IF_RO); }
 313 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RW"    { RTOKEN(ONLY_IF_RW); }
 314 <EXPRESSION,BOTH,SCRIPT>"SPECIAL"       { RTOKEN(SPECIAL); }
 315 <BOTH,SCRIPT>"o"                        { RTOKEN(ORIGIN);}
 316 <BOTH,SCRIPT>"org"                      { RTOKEN(ORIGIN);}
 317 <BOTH,SCRIPT>"l"                        { RTOKEN( LENGTH);}
 318 <BOTH,SCRIPT>"len"                      { RTOKEN( LENGTH);}
 319 <EXPRESSION,BOTH,SCRIPT>"INPUT_SECTION_FLAGS"   { RTOKEN(INPUT_SECTION_FLAGS); }
 320 <EXPRESSION,BOTH,SCRIPT>"INCLUDE"       { RTOKEN(INCLUDE);}
 321 <BOTH,SCRIPT>"PHDRS"                    { RTOKEN (PHDRS); }
 322 <EXPRESSION,BOTH,SCRIPT>"AT"            { RTOKEN(AT);}
 323 <EXPRESSION,BOTH,SCRIPT>"ALIGN_WITH_INPUT"      { RTOKEN(ALIGN_WITH_INPUT);}
 324 <EXPRESSION,BOTH,SCRIPT>"SUBALIGN"      { RTOKEN(SUBALIGN);}
 325 <EXPRESSION,BOTH,SCRIPT>"HIDDEN"        { RTOKEN(HIDDEN); }
 326 <EXPRESSION,BOTH,SCRIPT>"PROVIDE"       { RTOKEN(PROVIDE); }
 327 <EXPRESSION,BOTH,SCRIPT>"PROVIDE_HIDDEN" { RTOKEN(PROVIDE_HIDDEN); }
 328 <EXPRESSION,BOTH,SCRIPT>"KEEP"          { RTOKEN(KEEP); }
 329 <EXPRESSION,BOTH,SCRIPT>"EXCLUDE_FILE"  { RTOKEN(EXCLUDE_FILE); }
 330 <EXPRESSION,BOTH,SCRIPT>"CONSTANT"      { RTOKEN(CONSTANT);}
 331 <MRI>"#".*\n?                   { ++ lineno; }
 332 <MRI>"\n"                       { ++ lineno;  RTOKEN(NEWLINE); }
 333 <MRI>"*".*                      { /* Mri comment line */ }
 334 <MRI>";".*                      { /* Mri comment line */ }
 335 <MRI>"END"                      { RTOKEN(ENDWORD); }
 336 <MRI>"ALIGNMOD"                 { RTOKEN(ALIGNMOD);}
 337 <MRI>"ALIGN"                    { RTOKEN(ALIGN_K);}
 338 <MRI>"CHIP"                     { RTOKEN(CHIP); }
 339 <MRI>"BASE"                     { RTOKEN(BASE); }
 340 <MRI>"ALIAS"                    { RTOKEN(ALIAS); }
 341 <MRI>"TRUNCATE"                 { RTOKEN(TRUNCATE); }
 342 <MRI>"LOAD"                     { RTOKEN(LOAD); }
 343 <MRI>"PUBLIC"                   { RTOKEN(PUBLIC); }
 344 <MRI>"ORDER"                    { RTOKEN(ORDER); }
 345 <MRI>"NAME"                     { RTOKEN(NAMEWORD); }
 346 <MRI>"FORMAT"                   { RTOKEN(FORMAT); }
 347 <MRI>"CASE"                     { RTOKEN(CASE); }
 348 <MRI>"START"                    { RTOKEN(START); }
 349 <MRI>"LIST".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 350 <MRI>"SECT"                     { RTOKEN(SECT); }
 351 <EXPRESSION,BOTH,SCRIPT,MRI>"ABSOLUTE"                  { RTOKEN(ABSOLUTE); }
 352 <MRI>"end"                      { RTOKEN(ENDWORD); }
 353 <MRI>"alignmod"                 { RTOKEN(ALIGNMOD);}
 354 <MRI>"align"                    { RTOKEN(ALIGN_K);}
 355 <MRI>"chip"                     { RTOKEN(CHIP); }
 356 <MRI>"base"                     { RTOKEN(BASE); }
 357 <MRI>"alias"                    { RTOKEN(ALIAS); }
 358 <MRI>"truncate"                 { RTOKEN(TRUNCATE); }
 359 <MRI>"load"                     { RTOKEN(LOAD); }
 360 <MRI>"public"                   { RTOKEN(PUBLIC); }
 361 <MRI>"order"                    { RTOKEN(ORDER); }
 362 <MRI>"name"                     { RTOKEN(NAMEWORD); }
 363 <MRI>"format"                   { RTOKEN(FORMAT); }
 364 <MRI>"case"                     { RTOKEN(CASE); }
 365 <MRI>"extern"                   { RTOKEN(EXTERN); }
 366 <MRI>"start"                    { RTOKEN(START); }
 367 <MRI>"list".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 368 <MRI>"sect"                     { RTOKEN(SECT); }
 369 <EXPRESSION,BOTH,SCRIPT,MRI>"absolute"                  { RTOKEN(ABSOLUTE); }
 370
 371 <MRI>{FILENAMECHAR1}{NOCFILENAMECHAR}*  {
 372 /* Filename without commas, needed to parse mri stuff */
 373                                  yylval.name = xstrdup (yytext);
 374                                   return NAME;
 375                                 }
 376
 377
 378 <BOTH,INPUTLIST>{FILENAMECHAR1}{FILENAMECHAR}*  {
 379                                  yylval.name = xstrdup (yytext);
 380                                   return NAME;
 381                                 }
 382 <INPUTLIST>"="{FILENAMECHAR1}{FILENAMECHAR}*    {
 383 /* Filename to be prefixed by --sysroot or when non-sysrooted, nothing.  */
 384                                  yylval.name = xstrdup (yytext);
 385                                   return NAME;
 386                                 }
 387 <BOTH,INPUTLIST>"-l"{FILENAMECHAR}+ {
 388                                   yylval.name = xstrdup (yytext + 2);
 389                                   return LNAME;
 390                                 }
 391 <EXPRESSION>{FILENAMECHAR1}{NOCFILENAMECHAR}*   {
 392                                  yylval.name = xstrdup (yytext);
 393                                   return NAME;
 394                                 }
 395 <EXPRESSION>"-l"{NOCFILENAMECHAR}+ {
 396                                   yylval.name = xstrdup (yytext + 2);
 397                                   return LNAME;
 398                                 }
 399 <SCRIPT>{WILDCHAR}* {
 400                 /* Annoyingly, this pattern can match comments, and we have
 401                    longest match issues to consider.  So if the first two
 402                    characters are a comment opening, put the input back and
 403                    try again.  */
 404                 if (yytext[0] == '/' && yytext[1] == '*')
 405                   {
 406                     yyless (2);
 407                     comment ();
 408                   }
 409                 else
 410                   {
 411                     yylval.name = xstrdup (yytext);
 412                     return NAME;
 413                   }
 414         }
 415
 416 <EXPRESSION,BOTH,SCRIPT,VERS_NODE,INPUTLIST>"\""[^\"]*"\"" {
 417                                         /* No matter the state, quotes
 418                                            give what's inside */
 419                                         yylval.name = xstrdup (yytext + 1);
 420                                         yylval.name[yyleng - 2] = 0;
 421                                         return NAME;
 422                                 }
 423 <BOTH,SCRIPT,EXPRESSION>"\n"            { lineno++;}
 424 <MRI,BOTH,SCRIPT,EXPRESSION>[ \t\r]+    { }
 425
 426 <VERS_NODE,VERS_SCRIPT>[:,;]    { return *yytext; }
 427
 428 <VERS_NODE>global               { RTOKEN(GLOBAL); }
 429
 430 <VERS_NODE>local                { RTOKEN(LOCAL); }
 431
 432 <VERS_NODE>extern               { RTOKEN(EXTERN); }
 433
 434 <VERS_NODE>{V_IDENTIFIER}       { yylval.name = xstrdup (yytext);
 435                                   return VERS_IDENTIFIER; }
 436
 437 <VERS_SCRIPT>{V_TAG}            { yylval.name = xstrdup (yytext);
 438                                   return VERS_TAG; }
 439
 440 <VERS_START>"{"                 { BEGIN(VERS_SCRIPT); return *yytext; }
 441
 442 <VERS_SCRIPT>"{"                { BEGIN(VERS_NODE);
 443                                   vers_node_nesting = 0;
 444                                   return *yytext;
 445                                 }
 446 <VERS_SCRIPT>"}"                { return *yytext; }
 447 <VERS_NODE>"{"                  { vers_node_nesting++; return *yytext; }
 448 <VERS_NODE>"}"                  { if (--vers_node_nesting < 0)
 449                                     BEGIN(VERS_SCRIPT);
 450                                   return *yytext;
 451                                 }
 452
 453 <VERS_START,VERS_NODE,VERS_SCRIPT,INPUTLIST>[\n]        { lineno++; }
 454
 455 <VERS_START,VERS_NODE,VERS_SCRIPT>#.*           { /* Eat up comments */ }
 456
 457 <VERS_START,VERS_NODE,VERS_SCRIPT,INPUTLIST>[ \t\r]+    { /* Eat up whitespace */ }
 458
 459 <<EOF>> {
 460   include_stack_ptr--;
 461   if (include_stack_ptr == 0)
 462     {
 463       lineno = 0;
 464       yyterminate ();
 465     }
 466   else
 467     yy_switch_to_buffer (include_stack[include_stack_ptr]);
 468
 469   lineno = lineno_stack[include_stack_ptr];
 470   input_flags.sysrooted = sysrooted_stack[include_stack_ptr];
 471
 472   return END;
 473 }
 474
 475 <SCRIPT,MRI,VERS_START,VERS_SCRIPT,VERS_NODE>.  lex_warn_invalid (" in script", yytext);
 476 <EXPRESSION,DEFSYMEXP,BOTH>.    lex_warn_invalid (" in expression", yytext);
 477
 478 %%
 479 \f
 480
 481 /* Switch flex to reading script file NAME, open on FILE,
 482    saving the current input info on the include stack.  */
 483
 484 void
 485 lex_push_file (FILE *file, const char *name, unsigned int sysrooted)
 486 {
 487   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 488     {
 489       einfo ("%F:includes nested too deeply\n");
 490     }
 491   file_name_stack[include_stack_ptr] = name;
 492   lineno_stack[include_stack_ptr] = lineno;
 493   sysrooted_stack[include_stack_ptr] = input_flags.sysrooted;
 494   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 495
 496   include_stack_ptr++;
 497   lineno = 1;
 498   input_flags.sysrooted = sysrooted;
 499   yyin = file;
 500   yy_switch_to_buffer (yy_create_buffer (yyin, YY_BUF_SIZE));
 501 }
 502
 503 /* Return a newly created flex input buffer containing STRING,
 504    which is SIZE bytes long.  */
 505
 506 static YY_BUFFER_STATE
 507 yy_create_string_buffer (const char *string, size_t size)
 508 {
 509   YY_BUFFER_STATE b;
 510
 511   /* Calls to m-alloc get turned by sed into xm-alloc.  */
 512   b = malloc (sizeof (struct yy_buffer_state));
 513   b->yy_input_file = 0;
 514   b->yy_buf_size = size;
 515
 516   /* yy_ch_buf has to be 2 characters longer than the size given because
 517      we need to put in 2 end-of-buffer characters.  */
 518   b->yy_ch_buf = malloc ((unsigned) (b->yy_buf_size + 3));
 519
 520   b->yy_ch_buf[0] = '\n';
 521   strcpy (b->yy_ch_buf+1, string);
 522   b->yy_ch_buf[size+1] = YY_END_OF_BUFFER_CHAR;
 523   b->yy_ch_buf[size+2] = YY_END_OF_BUFFER_CHAR;
 524   b->yy_n_chars = size+1;
 525   b->yy_buf_pos = &b->yy_ch_buf[1];
 526
 527   b->yy_is_our_buffer = 1;
 528   b->yy_is_interactive = 0;
 529   b->yy_at_bol = 1;
 530   b->yy_fill_buffer = 0;
 531
 532   /* flex 2.4.7 changed the interface.  FIXME: We should not be using
 533      a flex internal interface in the first place!  */
 534 #ifdef YY_BUFFER_NEW
 535   b->yy_buffer_status = YY_BUFFER_NEW;
 536 #else
 537   b->yy_eof_status = EOF_NOT_SEEN;
 538 #endif
 539
 540   return b;
 541 }
 542
 543 /* Switch flex to reading from STRING, saving the current input info
 544    on the include stack.  */
 545
 546 void
 547 lex_redirect (const char *string, const char *fake_filename, unsigned int count)
 548 {
 549   YY_BUFFER_STATE tmp;
 550
 551   yy_init = 0;
 552   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 553     {
 554       einfo("%F: macros nested too deeply\n");
 555     }
 556   file_name_stack[include_stack_ptr] = fake_filename;
 557   lineno_stack[include_stack_ptr] = lineno;
 558   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 559   include_stack_ptr++;
 560   lineno = count;
 561   tmp = yy_create_string_buffer (string, strlen (string));
 562   yy_switch_to_buffer (tmp);
 563 }
 564 \f
 565 /* Functions to switch to a different flex start condition,
 566    saving the current start condition on `state_stack'.  */
 567
 568 static int state_stack[MAX_INCLUDE_DEPTH * 2];
 569 static int *state_stack_p = state_stack;
 570
 571 void
 572 ldlex_script (void)
 573 {
 574   *(state_stack_p)++ = yy_start;
 575   BEGIN (SCRIPT);
 576 }
 577
 578 void
 579 ldlex_inputlist (void)
 580 {
 581   *(state_stack_p)++ = yy_start;
 582   BEGIN (INPUTLIST);
 583 }
 584
 585 void
 586 ldlex_mri_script (void)
 587 {
 588   *(state_stack_p)++ = yy_start;
 589   BEGIN (MRI);
 590 }
 591
 592 void
 593 ldlex_version_script (void)
 594 {
 595   *(state_stack_p)++ = yy_start;
 596   BEGIN (VERS_START);
 597 }
 598
 599 void
 600 ldlex_version_file (void)
 601 {
 602   *(state_stack_p)++ = yy_start;
 603   BEGIN (VERS_SCRIPT);
 604 }
 605
 606 void
 607 ldlex_defsym (void)
 608 {
 609   *(state_stack_p)++ = yy_start;
 610   BEGIN (DEFSYMEXP);
 611 }
 612
 613 void
 614 ldlex_expression (void)
 615 {
 616   *(state_stack_p)++ = yy_start;
 617   BEGIN (EXPRESSION);
 618 }
 619
 620 void
 621 ldlex_both (void)
 622 {
 623   *(state_stack_p)++ = yy_start;
 624   BEGIN (BOTH);
 625 }
 626
 627 void
 628 ldlex_popstate (void)
 629 {
 630   yy_start = *(--state_stack_p);
 631 }
 632
 633 /* Return the current file name, or the previous file if no file is
 634    current.  */
 635
 636 const char*
 637 ldlex_filename (void)
 638 {
 639   return file_name_stack[include_stack_ptr - (include_stack_ptr != 0)];
 640 }
 641 \f
 642
 643 /* Place up to MAX_SIZE characters in BUF and return
 644    either the number of characters read, or 0 to indicate EOF.  */
 645
 646 static int
 647 yy_input (char *buf, int max_size)
 648 {
 649   int result = 0;
 650   if (YY_CURRENT_BUFFER->yy_input_file)
 651     {
 652       if (yyin)
 653         {
 654           result = fread (buf, 1, max_size, yyin);
 655           if (result < max_size && ferror (yyin))
 656             einfo ("%F%P: read in flex scanner failed\n");
 657         }
 658     }
 659   return result;
 660 }
 661
 662 /* Eat the rest of a C-style comment.  */
 663
 664 static void
 665 comment (void)
 666 {
 667   int c;
 668
 669   while (1)
 670   {
 671     c = input();
 672     while (c != '*' && c != EOF)
 673     {
 674       if (c == '\n')
 675         lineno++;
 676       c = input();
 677     }
 678
 679     if (c == '*')
 680     {
 681       c = input();
 682       while (c == '*')
 683        c = input();
 684       if (c == '/')
 685        break;                   /* found the end */
 686     }
 687
 688     if (c == '\n')
 689       lineno++;
 690
 691     if (c == EOF)
 692     {
 693       einfo( "%F%P: EOF in comment\n");
 694       break;
 695     }
 696   }
 697 }
 698
 699 /* Warn the user about a garbage character WHAT in the input
 700    in context WHERE.  */
 701
 702 static void
 703 lex_warn_invalid (char *where, char *what)
 704 {
 705   char buf[5];
 706
 707   /* If we have found an input file whose format we do not recognize,
 708      and we are therefore treating it as a linker script, and we find
 709      an invalid character, then most likely this is a real object file
 710      of some different format.  Treat it as such.  */
 711   if (ldfile_assumed_script)
 712     {
 713       bfd_set_error (bfd_error_file_not_recognized);
 714       einfo ("%F%s: file not recognized: %E\n", ldlex_filename ());
 715     }
 716
 717   if (! ISPRINT (*what))
 718     {
 719       sprintf (buf, "\\%03o", *(unsigned char *) what);
 720       what = buf;
 721     }
 722
 723   einfo ("%P:%S: ignoring invalid character `%s'%s\n", NULL, what, where);
 724 }