libiberty/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_PREREQ(2.64)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR([xmalloc.c])
   6
   7 # This works around the fact that libtool configuration may change LD
   8 # for this particular configuration, but some shells, instead of
   9 # keeping the changes in LD private, export them just because LD is
  10 # exported.  We don't use libtool yet, but some day we might, so...
  11 ORIGINAL_LD_FOR_MULTILIBS=$LD
  12
  13 dnl We use these options to decide which functions to include.
  14 AC_ARG_WITH(target-subdir,
  15 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  16 AC_ARG_WITH(build-subdir,
  17 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
  18 AC_ARG_WITH(cross-host,
  19 [  --with-cross-host=HOST           Configuring with a cross compiler])
  20 AC_ARG_WITH(newlib,
  21 [  --with-newlib                    Configuring with newlib])
  22
  23 if test "${srcdir}" = "."; then
  24   if test -n "${with_build_subdir}"; then
  25     libiberty_topdir="${srcdir}/../.."
  26     with_target_subdir=
  27   elif test -z "${with_target_subdir}"; then
  28     libiberty_topdir="${srcdir}/.."
  29   else
  30     if test "${with_target_subdir}" != "."; then
  31       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  32     else
  33       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  34     fi
  35   fi
  36 else
  37   libiberty_topdir="${srcdir}/.."
  38 fi
  39 AC_SUBST(libiberty_topdir)
  40 AC_CONFIG_AUX_DIR($libiberty_topdir)
  41
  42 dnl Very limited version of automake's enable-maintainer-mode
  43
  44 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  45   dnl maintainer-mode is disabled by default
  46   AC_ARG_ENABLE(maintainer-mode,
  47 [  --enable-maintainer-mode
  48                           enable make rules and dependencies not useful
  49                           (and sometimes confusing) to the casual installer],
  50       maintainer_mode=$enableval,
  51       maintainer_mode=no)
  52
  53 AC_MSG_RESULT($maintainer_mode)
  54
  55 if test "$maintainer_mode" = "yes"; then
  56   MAINT=''
  57   NOTMAINT='#'
  58 else
  59   MAINT='#'
  60   NOTMAINT=''
  61 fi
  62 AC_SUBST(MAINT)dnl
  63 AC_SUBST(NOTMAINT)dnl
  64
  65 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  66 # rely on it - libiberty is built before texinfo.
  67 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  68 if test "x$MAKEINFO" = "x"; then
  69     MAKEINFO="@echo makeinfo missing; true"
  70     BUILD_INFO=
  71 else
  72     BUILD_INFO=info
  73     case "$MAKEINFO" in
  74       */missing\ makeinfo*)
  75         BUILD_INFO=
  76         AC_MSG_WARN([
  77 *** Makeinfo is missing. Info documentation will not be built.])
  78         ;;
  79       *)
  80         case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
  81           x*\ [[1-3]].* )
  82             MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
  83             BUILD_INFO=
  84             AC_MSG_WARN([
  85 *** Makeinfo is too old. Info documentation will not be built.])
  86           ;;
  87         esac
  88         ;;
  89     esac
  90 fi
  91 AC_SUBST(MAKEINFO)
  92 AC_SUBST(BUILD_INFO)
  93
  94 AC_CHECK_PROG(PERL, perl, perl, )
  95 if test x"$PERL" = x""; then
  96   HAVE_PERL='#'
  97 else
  98   HAVE_PERL=''
  99 fi
 100 AC_SUBST(HAVE_PERL)
 101
 102 AC_CANONICAL_HOST
 103
 104 dnl When we start using automake:
 105 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
 106
 107 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 108 dnl to call AC_CHECK_PROG.
 109 AC_CHECK_TOOL(AR, ar)
 110 AC_CHECK_TOOL(RANLIB, ranlib, :)
 111
 112 dnl When switching to automake, replace the following with AM_ENABLE_MULTILIB.
 113 # Add --enable-multilib to configure.
 114 # Default to --enable-multilib
 115 AC_ARG_ENABLE(multilib,
 116 [  --enable-multilib       build many library versions (default)],
 117 [case "$enableval" in
 118   yes) multilib=yes ;;
 119   no)  multilib=no ;;
 120   *)   AC_MSG_ERROR([bad value $enableval for multilib option]) ;;
 121  esac],
 122               [multilib=yes])
 123
 124 # Even if the default multilib is not a cross compilation,
 125 # it may be that some of the other multilibs are.
 126 if test $cross_compiling = no && test $multilib = yes \
 127    && test "x${with_multisubdir}" != x ; then
 128    cross_compiling=maybe
 129 fi
 130
 131 # We may wish to install the target headers somewhere.
 132 AC_MSG_CHECKING([whether to install libiberty headers and static library])
 133 dnl install-libiberty is disabled by default
 134
 135 AC_ARG_ENABLE(install-libiberty,
 136 [  --enable-install-libiberty       Install headers and library for end users],
 137 enable_install_libiberty=$enableval,
 138 enable_install_libiberty=no)dnl
 139
 140 # Option parsed, now set things appropriately.
 141 case x"$enable_install_libiberty" in
 142   xyes|x)
 143     target_header_dir=libiberty
 144     ;;
 145   xno)
 146     target_header_dir=
 147     ;;
 148   *)
 149     # This could be sanity-checked in various ways...
 150     target_header_dir="${enable_install_libiberty}"
 151     ;;
 152 esac
 153 AC_MSG_RESULT($enable_install_libiberty)
 154 AC_MSG_NOTICE([target_header_dir = $target_header_dir])
 155
 156 GCC_NO_EXECUTABLES
 157 AC_PROG_CC
 158 AC_SYS_LARGEFILE
 159 AC_PROG_CPP_WERROR
 160
 161 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wc++-compat \
 162                           -Wstrict-prototypes], [ac_libiberty_warn_cflags])
 163 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([], [ac_libiberty_warn_cflags])
 164
 165 AC_PROG_CC_C_O
 166 # autoconf is lame and doesn't give us any substitution variable for this.
 167 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 168   NO_MINUS_C_MINUS_O=yes
 169 else
 170   OUTPUT_OPTION='-o $@'
 171 fi
 172 AC_SUBST(NO_MINUS_C_MINUS_O)
 173 AC_SUBST(OUTPUT_OPTION)
 174
 175 AC_C_CONST
 176 AC_C_INLINE
 177 AC_C_BIGENDIAN
 178
 179 dnl When we start using libtool:
 180 dnl Default to a non shared library.  This may be overridden by the
 181 dnl configure option --enable-shared.
 182 dnl AM_DISABLE_SHARED
 183
 184 dnl When we start using libtool:
 185 dnl AM_PROG_LIBTOOL
 186
 187 dnl When we start using automake:
 188 dnl AM_CONFIG_HEADER(config.h:config.in)
 189 AC_CONFIG_HEADER(config.h:config.in)
 190
 191 dnl When we start using automake:
 192 dnl AM_MAINTAINER_MODE
 193 dnl AC_EXEEXT
 194
 195 dnl When we start using automake:
 196 dnl AM_PROG_INSTALL
 197 AC_PROG_INSTALL
 198
 199 # Don't build the shared library for build.
 200 if [[ -n "${with_build_subdir}" ]]; then
 201   enable_shared=no
 202 fi
 203
 204 frag=
 205 case "${host}" in
 206   rs6000-ibm-aix3.1 | rs6000-ibm-aix)
 207                         frag=mh-aix ;;
 208   *-*-cxux7*)           frag=mh-cxux7 ;;
 209   *-*-freebsd2.1.*)     frag=mh-fbsd21 ;;
 210   *-*-freebsd2.2.[[012]])       frag=mh-fbsd21 ;;
 211   i370-*-opened*)       frag=mh-openedition ;;
 212   i[[34567]]86-*-windows*)      frag=mh-windows ;;
 213 esac
 214
 215 if [[ -n "${frag}" ]]; then
 216   frag=${libiberty_topdir}/libiberty/config/$frag
 217 fi
 218
 219 GCC_PICFLAG
 220
 221 # If they didn't specify --enable-shared, don't generate shared libs.
 222 case "${enable_shared}" in
 223   yes) shared=yes ;;
 224   no) shared=no ;;
 225   "") shared=no ;;
 226   *) shared=yes ;;
 227 esac
 228
 229 # ...unless --enable-host-shared was passed from top-level config:
 230 if [[ "${enable_host_shared}" = "yes" ]]; then
 231   shared=yes
 232 fi
 233
 234 if [[ "${shared}" != "yes" ]]; then
 235   PICFLAG=
 236 fi
 237 AC_SUBST(PICFLAG)
 238
 239 NOASANFLAG=
 240 case " ${CFLAGS} " in
 241   *\ -fsanitize=address\ *) NOASANFLAG=-fno-sanitize=address ;;
 242 esac
 243 AC_SUBST(NOASANFLAG)
 244
 245 echo "# Warning: this fragment is automatically generated" > temp-frag
 246
 247 if [[ -n "${frag}" ]] && [[ -f "${frag}" ]]; then
 248   echo "Appending ${frag} to xhost-mkfrag"
 249   echo "# Following fragment copied from ${frag}" >> temp-frag
 250   cat ${frag} >> temp-frag
 251 fi
 252
 253 # record if we want to build shared libs.
 254 if [[ "${shared}" = "yes" ]]; then
 255   echo enable_shared = yes >> temp-frag
 256 else
 257   echo enable_shared = no >> temp-frag
 258 fi
 259
 260 frag=xhost-mkfrag
 261 ${CONFIG_SHELL-/bin/sh} ${libiberty_topdir}/move-if-change temp-frag xhost-mkfrag
 262
 263 host_makefile_frag=${frag}
 264 AC_SUBST_FILE(host_makefile_frag)
 265
 266 # It's OK to check for header files.  Although the compiler may not be
 267 # able to link anything, it had better be able to at least compile
 268 # something.
 269 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h malloc.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h sys/sysctl.h sys/systemcfg.h stdint.h stdio_ext.h process.h sys/prctl.h)
 270 AC_HEADER_SYS_WAIT
 271 AC_HEADER_TIME
 272
 273 libiberty_AC_DECLARE_ERRNO
 274
 275 # Determine the size of an int for struct fibnode.
 276 AC_CHECK_SIZEOF([int])
 277
 278 # Look for a 64-bit type.
 279 AC_MSG_CHECKING([for a 64-bit type])
 280 AC_CACHE_VAL(liberty_cv_uint64,
 281 [AC_TRY_COMPILE(
 282 [#ifdef HAVE_STDINT_H
 283 #include <stdint.h>
 284 #endif],
 285 [extern uint64_t foo;],
 286 liberty_cv_uint64=uint64_t,
 287 [AC_TRY_COMPILE(
 288 [#ifdef HAVE_LIMITS_H
 289 #include <limits.h>
 290 #endif
 291 #ifndef CHAR_BIT
 292 #define CHAR_BIT 8
 293 #endif],
 294 [extern char foo[sizeof(long) * CHAR_BIT >= 64 ? 1 : -1];],
 295 liberty_cv_uint64="unsigned long",
 296 [AC_TRY_COMPILE(
 297 [#ifdef HAVE_LIMITS_H
 298 #include <limits.h>
 299 #endif
 300 #ifndef CHAR_BIT
 301 #define CHAR_BIT 8
 302 #endif],
 303 [extern char foo[sizeof(long long) * CHAR_BIT >= 64 ? 1 : -1];],
 304 liberty_cv_uint64="unsigned long long", liberty_cv_uint64=none)])])])
 305 AC_MSG_RESULT($liberty_cv_uint64)
 306 if test "$liberty_cv_uint64" != none; then
 307   AC_DEFINE_UNQUOTED(UNSIGNED_64BIT_TYPE, $liberty_cv_uint64,
 308                      [Define to an unsigned 64-bit type available in the compiler.])
 309 fi
 310
 311 AC_TYPE_INTPTR_T
 312 AC_TYPE_UINTPTR_T
 313 AC_TYPE_SSIZE_T
 314
 315 # Given the above check, we always have uintptr_t or a fallback
 316 # definition.  So define HAVE_UINTPTR_T in case any imported code
 317 # relies on it.
 318 AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
 319
 320 AC_TYPE_PID_T
 321
 322 # This is the list of functions which libiberty will provide if they
 323 # are not available on the host.
 324
 325 funcs="asprintf"
 326 funcs="$funcs atexit"
 327 funcs="$funcs basename"
 328 funcs="$funcs bcmp"
 329 funcs="$funcs bcopy"
 330 funcs="$funcs bsearch"
 331 funcs="$funcs bzero"
 332 funcs="$funcs calloc"
 333 funcs="$funcs clock"
 334 funcs="$funcs ffs"
 335 funcs="$funcs getcwd"
 336 funcs="$funcs getpagesize"
 337 funcs="$funcs gettimeofday"
 338 funcs="$funcs index"
 339 funcs="$funcs insque"
 340 funcs="$funcs memchr"
 341 funcs="$funcs memcmp"
 342 funcs="$funcs memcpy"
 343 funcs="$funcs memmem"
 344 funcs="$funcs memmove"
 345 funcs="$funcs mempcpy"
 346 funcs="$funcs memset"
 347 funcs="$funcs mkstemps"
 348 funcs="$funcs putenv"
 349 funcs="$funcs random"
 350 funcs="$funcs rename"
 351 funcs="$funcs rindex"
 352 funcs="$funcs setenv"
 353 funcs="$funcs snprintf"
 354 funcs="$funcs sigsetmask"
 355 funcs="$funcs stpcpy"
 356 funcs="$funcs stpncpy"
 357 funcs="$funcs strcasecmp"
 358 funcs="$funcs strchr"
 359 funcs="$funcs strdup"
 360 funcs="$funcs strncasecmp"
 361 funcs="$funcs strndup"
 362 funcs="$funcs strnlen"
 363 funcs="$funcs strrchr"
 364 funcs="$funcs strstr"
 365 funcs="$funcs strtod"
 366 funcs="$funcs strtol"
 367 funcs="$funcs strtoul"
 368 funcs="$funcs strverscmp"
 369 funcs="$funcs tmpnam"
 370 funcs="$funcs vasprintf"
 371 funcs="$funcs vfprintf"
 372 funcs="$funcs vprintf"
 373 funcs="$funcs vsnprintf"
 374 funcs="$funcs vsprintf"
 375 funcs="$funcs waitpid"
 376 funcs="$funcs setproctitle"
 377
 378 # Also in the old function.def file: alloca, vfork, getopt.
 379
 380 vars="sys_errlist sys_nerr sys_siglist"
 381
 382 checkfuncs="__fsetlocking canonicalize_file_name dup3 getrlimit getrusage \
 383  getsysinfo gettimeofday on_exit psignal pstat_getdynamic pstat_getstatic \
 384  realpath setrlimit sbrk spawnve spawnvpe strerror strsignal sysconf sysctl \
 385  sysmp table times wait3 wait4"
 386
 387 # These are neither executed nor required, but they help keep
 388 # autoheader happy without adding a bunch of text to acconfig.h.
 389 if test "x" = "y"; then
 390   AC_CHECK_FUNCS(asprintf atexit \
 391     basename bcmp bcopy bsearch bzero \
 392     calloc canonicalize_file_name clock \
 393     dup3 \
 394     ffs __fsetlocking \
 395     getcwd getpagesize getrlimit getrusage getsysinfo gettimeofday \
 396     index insque \
 397     memchr memcmp memcpy memmem memmove memset mkstemps \
 398     on_exit \
 399     psignal pstat_getdynamic pstat_getstatic putenv \
 400     random realpath rename rindex \
 401     sbrk setenv setproctitle setrlimit sigsetmask snprintf spawnve spawnvpe \
 402      stpcpy stpncpy strcasecmp strchr strdup \
 403      strerror strncasecmp strndup strnlen strrchr strsignal strstr strtod \
 404      strtol strtoul strverscmp sysconf sysctl sysmp \
 405     table times tmpnam \
 406     vasprintf vfprintf vprintf vsprintf \
 407     wait3 wait4 waitpid)
 408   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf])
 409   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 410   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 411   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 412 fi
 413
 414 # For each of these functions, if the host does not provide the
 415 # function we want to put FN.o in LIBOBJS, and if the host does
 416 # provide the function, we want to define HAVE_FN in config.h.
 417
 418 setobjs=
 419 CHECK=
 420 if test -n "${with_target_subdir}"; then
 421
 422   # We are being configured as a target library.  AC_REPLACE_FUNCS
 423   # may not work correctly, because the compiler may not be able to
 424   # link executables.  Note that we may still be being configured
 425   # native.
 426
 427   # If we are being configured for newlib, we know which functions
 428   # newlib provide and which ones we will be expected to provide.
 429
 430   if test "x${with_newlib}" = "xyes"; then
 431     AC_LIBOBJ([asprintf])
 432     AC_LIBOBJ([basename])
 433     AC_LIBOBJ([insque])
 434     AC_LIBOBJ([random])
 435     AC_LIBOBJ([strdup])
 436     AC_LIBOBJ([vasprintf])
 437
 438     for f in $funcs; do
 439       case "$f" in
 440         asprintf | basename | insque | random | strdup | vasprintf)
 441           ;;
 442         *)
 443           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 444           AC_DEFINE_UNQUOTED($n)
 445           ;;
 446       esac
 447     done
 448
 449     # newlib doesnt provide any of the variables in $vars, so we
 450     # dont have to check them here.
 451
 452     # Of the functions in $checkfuncs, newlib only has strerror.
 453     AC_DEFINE(HAVE_STRERROR)
 454
 455     setobjs=yes
 456
 457   fi
 458
 459   # If we are being configured for Mingw, we know which functions
 460   # Mingw provides and which ones we will be expected to provide.
 461
 462   case "${host}" in
 463   *-*-mingw*)
 464     AC_LIBOBJ([asprintf])
 465     AC_LIBOBJ([basename])
 466     AC_LIBOBJ([bcmp])
 467     AC_LIBOBJ([bcopy])
 468     AC_LIBOBJ([bzero])
 469     AC_LIBOBJ([clock])
 470     AC_LIBOBJ([ffs])
 471     AC_LIBOBJ([getpagesize])
 472     AC_LIBOBJ([index])
 473     AC_LIBOBJ([insque])
 474     AC_LIBOBJ([mempcpy])
 475     AC_LIBOBJ([mkstemps])
 476     AC_LIBOBJ([random])
 477     AC_LIBOBJ([rindex])
 478     AC_LIBOBJ([sigsetmask])
 479     AC_LIBOBJ([stpcpy])
 480     AC_LIBOBJ([stpncpy])
 481     AC_LIBOBJ([strndup])
 482     AC_LIBOBJ([strnlen])
 483     AC_LIBOBJ([strverscmp])
 484     AC_LIBOBJ([vasprintf])
 485     AC_LIBOBJ([waitpid])
 486
 487     for f in $funcs; do
 488       case "$f" in
 489         asprintf | basename | bcmp | bcopy | bzero | clock | ffs | getpagesize | index | insque | mempcpy | mkstemps | random | rindex | sigsetmask | stpcpy | stpncpy | strdup | strndup | strnlen | strverscmp | vasprintf | waitpid)
 490           ;;
 491         *)
 492           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 493           AC_DEFINE_UNQUOTED($n)
 494           ;;
 495       esac
 496     done
 497
 498     # Mingw doesnt provide any of the variables in $vars, so we
 499     # dont have to check them here.
 500
 501     # Of the functions in $checkfuncs, Mingw only has strerror.
 502     AC_DEFINE(HAVE_STRERROR)
 503
 504     setobjs=yes
 505     ;;
 506
 507   *-*-msdosdjgpp)
 508     AC_LIBOBJ([vasprintf])
 509     AC_LIBOBJ([vsnprintf])
 510     AC_LIBOBJ([snprintf])
 511     AC_LIBOBJ([asprintf])
 512
 513     for f in atexit basename bcmp bcopy bsearch bzero calloc clock ffs \
 514              getcwd getpagesize getrusage gettimeofday \
 515              index insque memchr memcmp memcpy memmove memset psignal \
 516              putenv random rename rindex sbrk setenv stpcpy strcasecmp \
 517              strchr strdup strerror strncasecmp strrchr strstr strtod \
 518              strtol strtoul sysconf times tmpnam vfprintf vprintf \
 519              vsprintf waitpid
 520     do
 521       n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 522       AC_DEFINE_UNQUOTED($n)
 523     done
 524
 525
 526     setobjs=yes
 527     ;;
 528
 529   esac
 530
 531 else
 532
 533    # Not a target library, so we set things up to run the test suite.
 534    CHECK=really-check
 535
 536 fi
 537
 538 AC_SUBST(CHECK)
 539 AC_SUBST(target_header_dir)
 540
 541 case "${host}" in
 542   *-*-cygwin* | *-*-mingw*)
 543     AC_DEFINE(HAVE_SYS_ERRLIST)
 544     AC_DEFINE(HAVE_SYS_NERR)
 545     ;;
 546 esac
 547
 548 if test -z "${setobjs}"; then
 549   case "${host}" in
 550
 551   *-*-vxworks*)
 552     # Handle VxWorks configuration specially, since on VxWorks the
 553     # libraries are actually on the target board, not in the file
 554     # system.
 555     AC_LIBOBJ([basename])
 556     AC_LIBOBJ([getpagesize])
 557     AC_LIBOBJ([insque])
 558     AC_LIBOBJ([random])
 559     AC_LIBOBJ([strcasecmp])
 560     AC_LIBOBJ([strncasecmp])
 561     AC_LIBOBJ([strdup])
 562     AC_LIBOBJ([vfork])
 563     AC_LIBOBJ([waitpid])
 564     AC_LIBOBJ([vasprintf])
 565     for f in $funcs; do
 566       case "$f" in
 567         basename | getpagesize | insque | random | strcasecmp)
 568           ;;
 569         strncasecmp | strdup | vfork | waitpid | vasprintf)
 570           ;;
 571         *)
 572           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 573           AC_DEFINE_UNQUOTED($n)
 574           ;;
 575       esac
 576     done
 577
 578     # VxWorks doesn't provide any of the variables in $vars, so we
 579     # don't have to check them here.
 580
 581     # Of the functions in $checkfuncs, VxWorks only has strerror.
 582     AC_DEFINE(HAVE_STRERROR)
 583
 584     setobjs=yes
 585     ;;
 586
 587   esac
 588 fi
 589
 590 if test -z "${setobjs}"; then
 591
 592   case "${host}" in
 593
 594   *-*-mingw32*)
 595     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 596     # macros, so the test below won't find them.
 597     libiberty_cv_var_sys_nerr=yes
 598     libiberty_cv_var_sys_errlist=yes
 599     ;;
 600
 601   *-*-msdosdjgpp*)
 602     # vfork and fork are stubs.
 603     ac_cv_func_vfork_works=no
 604     ;;
 605
 606   *-*-uwin*)
 607     # Under some versions of uwin, vfork is notoriously buggy and the test
 608     # can hang configure; on other versions, vfork exists just as a stub.
 609     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 610     ac_cv_func_vfork_works=no
 611     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 612     # macros (actually, these are imported from a DLL, but the end effect
 613     # is the same), so the test below won't find them.
 614     libiberty_cv_var_sys_nerr=yes
 615     libiberty_cv_var_sys_errlist=yes
 616     ;;
 617
 618   *-*-*vms*)
 619     # Under VMS, vfork works very different than on Unix. The standard test
 620     # won't work, and it isn't easily adaptable. It makes more sense to
 621     # just force it.
 622     ac_cv_func_vfork_works=yes
 623     ;;
 624
 625   esac
 626
 627   # We haven't set the list of objects yet.  Use the standard autoconf
 628   # tests.  This will only work if the compiler works.
 629   AC_ISC_POSIX
 630   AC_REPLACE_FUNCS($funcs)
 631   libiberty_AC_FUNC_C_ALLOCA
 632   AC_FUNC_FORK
 633   if test $ac_cv_func_vfork_works = no; then
 634     AC_LIBOBJ([vfork])
 635   fi
 636   # We only need _doprnt if we might use it to implement v*printf.
 637   if test $ac_cv_func_vprintf != yes \
 638      || test $ac_cv_func_vfprintf != yes \
 639      || test $ac_cv_func_vsprintf != yes; then
 640     AC_REPLACE_FUNCS(_doprnt)
 641   else
 642     AC_CHECK_FUNCS(_doprnt)
 643   fi
 644
 645   for v in $vars; do
 646     AC_MSG_CHECKING([for $v])
 647     AC_CACHE_VAL(libiberty_cv_var_$v,
 648       [AC_LINK_IFELSE([AC_LANG_PROGRAM([[int *p;]],[[extern int $v []; p = $v;]])],
 649                       [eval "libiberty_cv_var_$v=yes"],
 650                       [eval "libiberty_cv_var_$v=no"])])
 651     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 652       AC_MSG_RESULT(yes)
 653       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 654       AC_DEFINE_UNQUOTED($n)
 655     else
 656       AC_MSG_RESULT(no)
 657     fi
 658   done
 659
 660   # special check for _system_configuration because AIX <4.3.2 do not
 661   # contain the `physmem' member.
 662   AC_MSG_CHECKING([for external symbol _system_configuration])
 663   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/systemcfg.h>]],
 664                         [[double x = _system_configuration.physmem;]])],
 665     [AC_MSG_RESULT([yes])
 666     AC_DEFINE(HAVE__SYSTEM_CONFIGURATION, 1,
 667               [Define if you have the _system_configuration variable.])],
 668     [AC_MSG_RESULT([no])])
 669
 670   AC_CHECK_FUNCS($checkfuncs)
 671   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf])
 672   AC_CHECK_DECLS([calloc, getenv, getopt, malloc, realloc, sbrk])
 673   AC_CHECK_DECLS([strverscmp])
 674   libiberty_NEED_DECLARATION(canonicalize_file_name)
 675 fi
 676
 677 # Figure out which version of pexecute to use.
 678 case "${host}" in
 679      *-*-mingw* | *-*-winnt*)   pexecute=pex-win32  ;;
 680      *-*-msdosdjgpp*)           pexecute=pex-djgpp  ;;
 681      *-*-msdos*)                pexecute=pex-msdos  ;;
 682      *)                         pexecute=pex-unix   ;;
 683 esac
 684 AC_SUBST(pexecute)
 685
 686 libiberty_AC_FUNC_STRNCMP
 687
 688 # Install a library built with a cross compiler in $(tooldir) rather
 689 # than $(libdir).
 690 if test -z "${with_cross_host}"; then
 691   INSTALL_DEST=libdir
 692 else
 693   INSTALL_DEST=tooldir
 694 fi
 695 AC_SUBST(INSTALL_DEST)
 696
 697 m4_pattern_allow(LIBOBJS)
 698 L=""
 699 for l in x $LIBOBJS; do
 700   case $l in
 701     x) ;;
 702     *) L="$L ./$l" ;;
 703   esac
 704 done
 705 LIBOBJS="$L"
 706
 707 dnl Required by html and install-html
 708 AC_SUBST(datarootdir)
 709 AC_SUBST(docdir)
 710 AC_SUBST(htmldir)
 711
 712 # We need multilib support, but only if configuring for the target.
 713 AC_CONFIG_FILES([Makefile testsuite/Makefile])
 714 AC_CONFIG_COMMANDS([default],
 715   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 716 if test -n "$CONFIG_FILES"; then
 717   if test -n "${with_target_subdir}"; then
 718     # FIXME: We shouldn't need to set ac_file
 719     ac_file=Makefile
 720     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 721     . ${libiberty_topdir}/config-ml.in
 722   fi
 723 fi]],
 724 [[srcdir=${srcdir}
 725 host=${host}
 726 target=${target}
 727 with_target_subdir=${with_target_subdir}
 728 with_multisubdir=${with_multisubdir}
 729 ac_configure_args="--enable-multilib ${ac_configure_args}"
 730 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 731 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 732 libiberty_topdir=${libiberty_topdir}
 733 ]])
 734 AC_OUTPUT