m4/extensions.m4

   1 # serial 13  -*- Autoconf -*-
   2 # Enable extensions on systems that normally disable them.
   3
   4 # Copyright (C) 2003, 2006-2016 Free Software Foundation, Inc.
   5 # This file is free software; the Free Software Foundation
   6 # gives unlimited permission to copy and/or distribute it,
   7 # with or without modifications, as long as this notice is preserved.
   8
   9 # This definition of AC_USE_SYSTEM_EXTENSIONS is stolen from git
  10 # Autoconf.  Perhaps we can remove this once we can assume Autoconf
  11 # 2.70 or later everywhere, but since Autoconf mutates rapidly
  12 # enough in this area it's likely we'll need to redefine
  13 # AC_USE_SYSTEM_EXTENSIONS for quite some time.
  14
  15 # If autoconf reports a warning
  16 #     warning: AC_COMPILE_IFELSE was called before AC_USE_SYSTEM_EXTENSIONS
  17 # or  warning: AC_RUN_IFELSE was called before AC_USE_SYSTEM_EXTENSIONS
  18 # the fix is
  19 #   1) to ensure that AC_USE_SYSTEM_EXTENSIONS is never directly invoked
  20 #      but always AC_REQUIREd,
  21 #   2) to ensure that for each occurrence of
  22 #        AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
  23 #      or
  24 #        AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  25 #      the corresponding gnulib module description has 'extensions' among
  26 #      its dependencies. This will ensure that the gl_USE_SYSTEM_EXTENSIONS
  27 #      invocation occurs in gl_EARLY, not in gl_INIT.
  28
  29 # AC_USE_SYSTEM_EXTENSIONS
  30 # ------------------------
  31 # Enable extensions on systems that normally disable them,
  32 # typically due to standards-conformance issues.
  33 #
  34 # Remember that #undef in AH_VERBATIM gets replaced with #define by
  35 # AC_DEFINE.  The goal here is to define all known feature-enabling
  36 # macros, then, if reports of conflicts are made, disable macros that
  37 # cause problems on some platforms (such as __EXTENSIONS__).
  38 AC_DEFUN_ONCE([AC_USE_SYSTEM_EXTENSIONS],
  39 [AC_BEFORE([$0], [AC_COMPILE_IFELSE])dnl
  40 AC_BEFORE([$0], [AC_RUN_IFELSE])dnl
  41
  42   AC_CHECK_HEADER([minix/config.h], [MINIX=yes], [MINIX=])
  43   if test "$MINIX" = yes; then
  44     AC_DEFINE([_POSIX_SOURCE], [1],
  45       [Define to 1 if you need to in order for 'stat' and other
  46        things to work.])
  47     AC_DEFINE([_POSIX_1_SOURCE], [2],
  48       [Define to 2 if the system does not provide POSIX.1 features
  49        except with this defined.])
  50     AC_DEFINE([_MINIX], [1],
  51       [Define to 1 if on MINIX.])
  52     AC_DEFINE([_NETBSD_SOURCE], [1],
  53       [Define to 1 to make NetBSD features available.  MINIX 3 needs this.])
  54   fi
  55
  56 dnl Use a different key than __EXTENSIONS__, as that name broke existing
  57 dnl configure.ac when using autoheader 2.62.
  58   AH_VERBATIM([USE_SYSTEM_EXTENSIONS],
  59 [/* Enable extensions on AIX 3, Interix.  */
  60 #ifndef _ALL_SOURCE
  61 # undef _ALL_SOURCE
  62 #endif
  63 /* Enable general extensions on OS X.  */
  64 #ifndef _DARWIN_C_SOURCE
  65 # undef _DARWIN_C_SOURCE
  66 #endif
  67 /* Enable GNU extensions on systems that have them.  */
  68 #ifndef _GNU_SOURCE
  69 # undef _GNU_SOURCE
  70 #endif
  71 /* Use GNU style printf and scanf.  */
  72 #ifndef __USE_MINGW_ANSI_STDIO
  73 # undef __USE_MINGW_ANSI_STDIO
  74 #endif
  75 /* Enable threading extensions on Solaris.  */
  76 #ifndef _POSIX_PTHREAD_SEMANTICS
  77 # undef _POSIX_PTHREAD_SEMANTICS
  78 #endif
  79 /* Enable extensions on HP NonStop.  */
  80 #ifndef _TANDEM_SOURCE
  81 # undef _TANDEM_SOURCE
  82 #endif
  83 /* Enable X/Open extensions if necessary.  HP-UX 11.11 defines
  84    mbstate_t only if _XOPEN_SOURCE is defined to 500, regardless of
  85    whether compiling with -Ae or -D_HPUX_SOURCE=1.  */
  86 #ifndef _XOPEN_SOURCE
  87 # undef _XOPEN_SOURCE
  88 #endif
  89 /* Enable general extensions on Solaris.  */
  90 #ifndef __EXTENSIONS__
  91 # undef __EXTENSIONS__
  92 #endif
  93 ])
  94   AC_CACHE_CHECK([whether it is safe to define __EXTENSIONS__],
  95     [ac_cv_safe_to_define___extensions__],
  96     [AC_COMPILE_IFELSE(
  97        [AC_LANG_PROGRAM([[
  98 #         define __EXTENSIONS__ 1
  99           ]AC_INCLUDES_DEFAULT])],
 100        [ac_cv_safe_to_define___extensions__=yes],
 101        [ac_cv_safe_to_define___extensions__=no])])
 102   test $ac_cv_safe_to_define___extensions__ = yes &&
 103     AC_DEFINE([__EXTENSIONS__])
 104   AC_DEFINE([_ALL_SOURCE])
 105   AC_DEFINE([_DARWIN_C_SOURCE])
 106   AC_DEFINE([_GNU_SOURCE])
 107   AC_DEFINE([__USE_MINGW_ANSI_STDIO])
 108   AC_DEFINE([_POSIX_PTHREAD_SEMANTICS])
 109   AC_DEFINE([_TANDEM_SOURCE])
 110   AC_CACHE_CHECK([whether _XOPEN_SOURCE should be defined],
 111     [ac_cv_should_define__xopen_source],
 112     [ac_cv_should_define__xopen_source=no
 113      AC_COMPILE_IFELSE(
 114        [AC_LANG_PROGRAM([[
 115           #include <wchar.h>
 116           mbstate_t x;]])],
 117        [],
 118        [AC_COMPILE_IFELSE(
 119           [AC_LANG_PROGRAM([[
 120              #define _XOPEN_SOURCE 500
 121              #include <wchar.h>
 122              mbstate_t x;]])],
 123           [ac_cv_should_define__xopen_source=yes])])])
 124   test $ac_cv_should_define__xopen_source = yes &&
 125     AC_DEFINE([_XOPEN_SOURCE], [500])
 126 ])# AC_USE_SYSTEM_EXTENSIONS
 127
 128 # gl_USE_SYSTEM_EXTENSIONS
 129 # ------------------------
 130 # Enable extensions on systems that normally disable them,
 131 # typically due to standards-conformance issues.
 132 AC_DEFUN_ONCE([gl_USE_SYSTEM_EXTENSIONS],
 133 [
 134   dnl Require this macro before AC_USE_SYSTEM_EXTENSIONS.
 135   dnl gnulib does not need it. But if it gets required by third-party macros
 136   dnl after AC_USE_SYSTEM_EXTENSIONS is required, autoconf 2.62..2.63 emit a
 137   dnl warning: "AC_COMPILE_IFELSE was called before AC_USE_SYSTEM_EXTENSIONS".
 138   dnl Note: We can do this only for one of the macros AC_AIX, AC_GNU_SOURCE,
 139   dnl AC_MINIX. If people still use AC_AIX or AC_MINIX, they are out of luck.
 140   AC_REQUIRE([AC_GNU_SOURCE])
 141
 142   AC_REQUIRE([AC_USE_SYSTEM_EXTENSIONS])
 143 ])