opcodes/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([z8k-dis.c])
   7
   8 AC_CANONICAL_TARGET
   9 AC_ISC_POSIX
  10
  11 # We currently only use the version number for the name of any shared
  12 # library.  For user convenience, we always use the same version
  13 # number that BFD is using.
  14 changequote(,)dnl
  15 BFD_VERSION=`sed -n -e 's/^.._INIT_AUTOMAKE.*,[         ]*\([^  ]*\)[   ]*).*/\1/p' < ${srcdir}/../bfd/configure.in`
  16 changequote([,])dnl
  17
  18 AM_INIT_AUTOMAKE(opcodes, ${BFD_VERSION})
  19
  20 AC_PROG_CC
  21 AC_GNU_SOURCE
  22 AC_USE_SYSTEM_EXTENSIONS
  23
  24 dnl These must be called before LT_INIT, because it may want
  25 dnl to call AC_CHECK_PROG.
  26 AC_CHECK_TOOL(AR, ar)
  27 AC_CHECK_TOOL(RANLIB, ranlib, :)
  28
  29 dnl Default to a non shared library.  This may be overridden by the
  30 dnl configure option --enable-shared.
  31 AC_DISABLE_SHARED
  32
  33 LT_INIT
  34
  35 AC_ARG_ENABLE(targets,
  36 [  --enable-targets        alternative target configurations],
  37 [case "${enableval}" in
  38   yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
  39             ;;
  40   no)       enable_targets= ;;
  41   *)        enable_targets=$enableval ;;
  42 esac])dnl
  43 AC_ARG_ENABLE(commonbfdlib,
  44 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  45 [case "${enableval}" in
  46   yes) commonbfdlib=true ;;
  47   no)  commonbfdlib=false ;;
  48   *)   AC_MSG_ERROR([bad value ${enableval} for opcodes commonbfdlib option]) ;;
  49 esac])dnl
  50
  51 AM_BINUTILS_WARNINGS
  52
  53 AC_CONFIG_HEADERS(config.h:config.in)
  54
  55 if test -z "$target" ; then
  56     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  57 fi
  58
  59 AM_MAINTAINER_MODE
  60 AM_INSTALL_LIBBFD
  61 AC_EXEEXT
  62
  63 # host-specific stuff:
  64
  65 ALL_LINGUAS="fr sv tr es da de id pt_BR ro nl fi vi ga zh_CN"
  66 ZW_GNU_GETTEXT_SISTER_DIR
  67 AM_PO_SUBDIRS
  68
  69 . ${srcdir}/../bfd/configure.host
  70
  71 BFD_CC_FOR_BUILD
  72
  73 AC_SUBST(HDEFINES)
  74 AC_PROG_INSTALL
  75
  76 AC_CHECK_HEADERS(string.h strings.h stdlib.h limits.h)
  77
  78 AC_CHECK_DECLS([basename, stpcpy])
  79
  80 cgen_maint=no
  81 cgendir='$(srcdir)/../cgen'
  82
  83 AC_ARG_ENABLE(cgen-maint,
  84 [  --enable-cgen-maint[=dir]    build cgen generated files],
  85 [case "${enableval}" in
  86   yes)  cgen_maint=yes ;;
  87   no)   cgen_maint=no ;;
  88   *)
  89         # argument is cgen install directory (not implemented yet).
  90         # Having a `share' directory might be more appropriate for the .scm,
  91         # .cpu, etc. files.
  92         cgen_maint=yes
  93         cgendir=${cgen_maint}/lib/cgen
  94         ;;
  95 esac])dnl
  96 AM_CONDITIONAL(CGEN_MAINT, test x${cgen_maint} = xyes)
  97 AC_SUBST(cgendir)
  98
  99 using_cgen=no
 100
 101 # Horrible hacks to build DLLs on Windows and a shared library elsewhere.
 102 SHARED_LDFLAGS=
 103 SHARED_LIBADD=
 104 SHARED_DEPENDENCIES=
 105 if test "$enable_shared" = "yes"; then
 106   case "${host}" in
 107     *-*-cygwin*)
 108       SHARED_LDFLAGS="-no-undefined"
 109       SHARED_LIBADD="-L`pwd`/../bfd -lbfd -L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin"
 110       ;;
 111    *-*-darwin*)
 112      SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.dylib"
 113      SHARED_DEPENDENCIES="../bfd/libbfd.la"
 114      ;;
 115     *)
 116       case "$host_vendor" in
 117         hp)
 118           SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.sl"
 119           ;;
 120         *)
 121           # It is tempting to include libiberty here as well, but
 122           # that library is only built as a static version.
 123           # Including it here would insert text relocations into
 124           # the opcodes library, which is undesirable.
 125           SHARED_LIBADD="-Wl,`pwd`/../bfd/.libs/libbfd.so"
 126           ;;
 127       esac
 128       SHARED_DEPENDENCIES="../bfd/libbfd.la"
 129       ;;
 130   esac
 131 fi
 132 AC_SUBST(SHARED_LDFLAGS)
 133 AC_SUBST(SHARED_LIBADD)
 134 AC_SUBST(SHARED_DEPENDENCIES)
 135
 136 # target-specific stuff:
 137
 138 # Canonicalize the secondary target names.
 139 if test -n "$enable_targets" ; then
 140     for targ in `echo $enable_targets | sed 's/,/ /g'`
 141     do
 142         result=`$ac_config_sub $targ 2>/dev/null`
 143         if test -n "$result" ; then
 144             canon_targets="$canon_targets $result"
 145         else
 146             # Allow targets that config.sub doesn't recognize, like "all".
 147             canon_targets="$canon_targets $targ"
 148         fi
 149     done
 150 fi
 151
 152 all_targets=false
 153 selarchs=
 154 for targ in $target $canon_targets
 155 do
 156     if test "x$targ" = "xall" ; then
 157         all_targets=true
 158     else
 159         . $srcdir/../bfd/config.bfd
 160         selarchs="$selarchs $targ_archs"
 161     fi
 162 done
 163
 164 # Utility var, documents generic cgen support files.
 165
 166 cgen_files="cgen-opc.lo cgen-asm.lo cgen-dis.lo cgen-bitset.lo"
 167
 168 # We don't do any links based on the target system, just makefile config.
 169
 170 if test x${all_targets} = xfalse ; then
 171
 172     # Target architecture .o files.
 173     ta=
 174
 175     for arch in $selarchs
 176     do
 177         ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g`
 178         archdefs="$archdefs -DARCH_$ad"
 179         case "$arch" in
 180         bfd_alpha_arch)         ta="$ta alpha-dis.lo alpha-opc.lo" ;;
 181         bfd_arc_arch)           ta="$ta arc-dis.lo arc-opc.lo arc-ext.lo" ;;
 182         bfd_arm_arch)           ta="$ta arm-dis.lo" ;;
 183         bfd_avr_arch)           ta="$ta avr-dis.lo" ;;
 184         bfd_bfin_arch)          ta="$ta bfin-dis.lo" ;;
 185         bfd_cr16_arch)          ta="$ta cr16-dis.lo cr16-opc.lo" ;;
 186         bfd_cris_arch)          ta="$ta cris-dis.lo cris-opc.lo cgen-bitset.lo" ;;
 187         bfd_crx_arch)           ta="$ta crx-dis.lo crx-opc.lo" ;;
 188         bfd_d10v_arch)          ta="$ta d10v-dis.lo d10v-opc.lo" ;;
 189         bfd_d30v_arch)          ta="$ta d30v-dis.lo d30v-opc.lo" ;;
 190         bfd_dlx_arch)           ta="$ta dlx-dis.lo" ;;
 191         bfd_fr30_arch)          ta="$ta fr30-asm.lo fr30-desc.lo fr30-dis.lo fr30-ibld.lo fr30-opc.lo" using_cgen=yes ;;
 192         bfd_frv_arch)           ta="$ta frv-asm.lo frv-desc.lo frv-dis.lo frv-ibld.lo frv-opc.lo" using_cgen=yes ;;
 193         bfd_h8300_arch)         ta="$ta h8300-dis.lo" ;;
 194         bfd_h8500_arch)         ta="$ta h8500-dis.lo" ;;
 195         bfd_hppa_arch)          ta="$ta hppa-dis.lo" ;;
 196         bfd_i370_arch)          ta="$ta i370-dis.lo i370-opc.lo" ;;
 197         bfd_i386_arch)          ta="$ta i386-dis.lo i386-opc.lo" ;;
 198         bfd_i860_arch)          ta="$ta i860-dis.lo" ;;
 199         bfd_i960_arch)          ta="$ta i960-dis.lo" ;;
 200         bfd_ia64_arch)          ta="$ta ia64-dis.lo ia64-opc.lo" ;;
 201         bfd_ip2k_arch)          ta="$ta ip2k-asm.lo ip2k-desc.lo ip2k-dis.lo ip2k-ibld.lo ip2k-opc.lo" using_cgen=yes ;;
 202         bfd_iq2000_arch)        ta="$ta iq2000-asm.lo iq2000-desc.lo iq2000-dis.lo iq2000-ibld.lo iq2000-opc.lo" using_cgen=yes ;;
 203         bfd_lm32_arch)          ta="$ta lm32-asm.lo lm32-desc.lo lm32-dis.lo lm32-ibld.lo lm32-opc.lo lm32-opinst.lo" using_cgen=yes ;;
 204         bfd_m32c_arch)          ta="$ta m32c-asm.lo m32c-desc.lo m32c-dis.lo m32c-ibld.lo m32c-opc.lo" using_cgen=yes ;;
 205         bfd_m32r_arch)          ta="$ta m32r-asm.lo m32r-desc.lo m32r-dis.lo m32r-ibld.lo m32r-opc.lo m32r-opinst.lo" using_cgen=yes ;;
 206         bfd_m68hc11_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 207         bfd_m68hc12_arch)       ta="$ta m68hc11-dis.lo m68hc11-opc.lo" ;;
 208         bfd_m68k_arch)          ta="$ta m68k-dis.lo m68k-opc.lo" ;;
 209         bfd_m88k_arch)          ta="$ta m88k-dis.lo" ;;
 210         bfd_maxq_arch)          ta="$ta maxq-dis.lo" ;;
 211         bfd_mcore_arch)         ta="$ta mcore-dis.lo" ;;
 212         bfd_mep_arch)           ta="$ta mep-asm.lo mep-desc.lo mep-dis.lo mep-ibld.lo mep-opc.lo" using_cgen=yes ;;
 213         bfd_mips_arch)          ta="$ta mips-dis.lo mips-opc.lo mips16-opc.lo" ;;
 214         bfd_mmix_arch)          ta="$ta mmix-dis.lo mmix-opc.lo" ;;
 215         bfd_mn10200_arch)       ta="$ta m10200-dis.lo m10200-opc.lo" ;;
 216         bfd_mn10300_arch)       ta="$ta m10300-dis.lo m10300-opc.lo" ;;
 217         bfd_mt_arch)            ta="$ta mt-asm.lo mt-desc.lo mt-dis.lo mt-ibld.lo mt-opc.lo" using_cgen=yes ;;
 218         bfd_msp430_arch)        ta="$ta msp430-dis.lo" ;;
 219         bfd_ns32k_arch)         ta="$ta ns32k-dis.lo" ;;
 220         bfd_openrisc_arch)      ta="$ta openrisc-asm.lo openrisc-desc.lo openrisc-dis.lo openrisc-ibld.lo openrisc-opc.lo" using_cgen=yes ;;
 221         bfd_or32_arch)          ta="$ta or32-dis.lo or32-opc.lo" using_cgen=yes ;;
 222         bfd_pdp11_arch)         ta="$ta pdp11-dis.lo pdp11-opc.lo" ;;
 223         bfd_pj_arch)            ta="$ta pj-dis.lo pj-opc.lo" ;;
 224         bfd_powerpc_arch)       ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 225         bfd_powerpc_64_arch)    ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 226         bfd_pyramid_arch)       ;;
 227         bfd_romp_arch)          ;;
 228         bfd_rs6000_arch)        ta="$ta ppc-dis.lo ppc-opc.lo" ;;
 229         bfd_s390_arch)          ta="$ta s390-dis.lo s390-opc.lo" ;;
 230         bfd_score_arch)         ta="$ta score-dis.lo" ;;
 231         bfd_sh_arch)
 232           # We can't decide what we want just from the CPU family.
 233           # We want SH5 support unless a specific version of sh is
 234           # specified, as in sh3-elf, sh3b-linux-gnu, etc.
 235           # Include it just for ELF targets, since the SH5 bfd:s are ELF only.
 236           for t in $target $canon_targets; do
 237             case $t in
 238               all |  sh5*-* | sh64*-* | sh-*-*elf* | shl*-*-*elf* | \
 239               sh-*-linux* | shl-*-linux*)
 240                                 ta="$ta sh64-dis.lo sh64-opc.lo"
 241                                 archdefs="$archdefs -DINCLUDE_SHMEDIA"
 242                                 break;;
 243             esac;
 244           done
 245                                 ta="$ta sh-dis.lo cgen-bitset.lo" ;;
 246         bfd_sparc_arch)         ta="$ta sparc-dis.lo sparc-opc.lo" ;;
 247         bfd_spu_arch)           ta="$ta spu-dis.lo spu-opc.lo" ;;
 248         bfd_tahoe_arch)         ;;
 249         bfd_tic30_arch)         ta="$ta tic30-dis.lo" ;;
 250         bfd_tic4x_arch)         ta="$ta tic4x-dis.lo" ;;
 251         bfd_tic54x_arch)        ta="$ta tic54x-dis.lo tic54x-opc.lo" ;;
 252         bfd_tic80_arch)         ta="$ta tic80-dis.lo tic80-opc.lo" ;;
 253         bfd_v850_arch)          ta="$ta v850-opc.lo v850-dis.lo" ;;
 254         bfd_v850e_arch)         ta="$ta v850-opc.lo v850-dis.lo" ;;
 255         bfd_v850ea_arch)        ta="$ta v850-opc.lo v850-dis.lo" ;;
 256         bfd_vax_arch)           ta="$ta vax-dis.lo" ;;
 257         bfd_w65_arch)           ta="$ta w65-dis.lo" ;;
 258         bfd_we32k_arch)         ;;
 259         bfd_xc16x_arch)         ta="$ta xc16x-asm.lo xc16x-desc.lo xc16x-dis.lo xc16x-ibld.lo xc16x-opc.lo" using_cgen=yes ;;
 260         bfd_xstormy16_arch)     ta="$ta xstormy16-asm.lo xstormy16-desc.lo xstormy16-dis.lo xstormy16-ibld.lo xstormy16-opc.lo" using_cgen=yes ;;
 261         bfd_xtensa_arch)        ta="$ta xtensa-dis.lo" ;;
 262         bfd_z80_arch)           ta="$ta z80-dis.lo" ;;
 263         bfd_z8k_arch)           ta="$ta z8k-dis.lo" ;;
 264
 265         "")                     ;;
 266         *)              AC_MSG_ERROR(*** unknown target architecture $arch) ;;
 267         esac
 268     done
 269
 270     if test $using_cgen = yes ; then
 271         ta="$ta $cgen_files"
 272     fi
 273
 274     # Weed out duplicate .o files.
 275     f=""
 276     for i in $ta ; do
 277         case " $f " in
 278         *" $i "*) ;;
 279         *) f="$f $i" ;;
 280         esac
 281     done
 282     ta="$f"
 283
 284     # And duplicate -D flags.
 285     f=""
 286     for i in $archdefs ; do
 287         case " $f " in
 288         *" $i "*) ;;
 289         *) f="$f $i" ;;
 290         esac
 291     done
 292     archdefs="$f"
 293
 294     BFD_MACHINES="$ta"
 295
 296 else    # all_targets is true
 297     archdefs=-DARCH_all
 298     BFD_MACHINES='$(ALL_MACHINES)'
 299 fi
 300
 301 AC_SUBST(archdefs)
 302 AC_SUBST(BFD_MACHINES)
 303
 304 AC_CONFIG_FILES([Makefile po/Makefile.in:po/Make-in])
 305 AC_OUTPUT