opcodes/configure.in

   1 AC_PREREQ(2.5)
   2 AC_INIT(z8k-dis.c)
   3 #    configure.in script for the opcodes library.
   4 #    Copyright (C) 1995, 1996 Free Software Foundation, Inc.
   5 #    Written by Cygnus Support.
   6 #
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 2 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  20
  21 AC_ARG_ENABLE(targets,
  22 [  --enable-targets        alternative target configurations],
  23 [case "${enableval}" in
  24   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  25             ;;
  26   no)       enable_targets= ;;
  27   *)        enable_targets=$enableval ;;
  28 esac])dnl
  29 AC_ARG_ENABLE(shared,
  30 [  --enable-shared         build shared opcodes library],
  31 [case "${enableval}" in
  32   yes) shared=true ;;
  33   no)  shared=false ;;
  34   *opcodes*) shared=true ;;
  35   *) shared=false ;;
  36 esac])dnl
  37 AC_ARG_ENABLE(commonbfdlib,
  38 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  39 [case "${enableval}" in
  40   yes) commonbfdlib=true ;;
  41   no)  commonbfdlib=false ;;
  42   *)   AC_MSG_ERROR([bad value ${enableval} for opcodes commonbfdlib option]) ;;
  43 esac])dnl
  44
  45 AC_CONFIG_HEADER(config.h:config.in)
  46
  47 AC_CONFIG_AUX_DIR(`cd $srcdir/..;pwd`)
  48 AC_CANONICAL_SYSTEM
  49 if test -z "$target" ; then
  50     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  51 fi
  52 AC_ARG_PROGRAM
  53
  54 # host-specific stuff:
  55
  56 ALLLIBS='$(TARGETLIB)'
  57 PICFLAG=
  58 SHLIB=unused-shlib
  59 SHLINK=unused-shlink
  60 if test "${shared}" = "true"; then
  61   ALLLIBS='$(TARGETLIB) $(SHLIB) $(SHLINK)'
  62   PICFLAG=-fpic
  63   if test "${commonbfdlib}" = "true"; then
  64 changequote(,)dnl
  65     SHLIB=../bfd/libbfd.so.`sed -e 's/[^0-9]*\([0-9.]*\).*/\1/' ${srcdir}/../bfd/VERSION`
  66 changequote([,])dnl
  67     SHLINK=../bfd/libbfd.so
  68   else
  69 changequote(,)dnl
  70     SHLIB=libopcodes.so.`sed -e 's/[^0-9]*\([0-9.]*\).*/\1/' ${srcdir}/../bfd/VERSION`
  71 changequote([,])dnl
  72     SHLINK=libopcodes.so
  73   fi
  74 fi
  75
  76 AC_PROG_CC
  77
  78 . ${srcdir}/../bfd/configure.host
  79
  80 AC_SUBST(HDEFINES)
  81 AC_CHECK_TOOL(AR, ar)
  82 AC_CHECK_TOOL(RANLIB, ranlib, :)
  83 AC_PROG_INSTALL
  84
  85 if test "${shared}" = "true"; then
  86   if test "${GCC}" != "yes" && test "${shared_non_gcc}" != "yes"; then
  87     AC_MSG_WARN([opcodes --enable-shared only supported when using gcc])
  88     shared=false
  89     ALLLIBS='$(TARGETLIB)'
  90     PICFLAG=
  91     SHLIB=unused-shlib
  92   fi
  93 fi
  94
  95 AC_SUBST(ALLLIBS)
  96 AC_SUBST(PICFLAG)
  97 AC_SUBST(SHLIB)
  98 AC_SUBST(SHLIB_CC)
  99 AC_SUBST(SHLIB_CFLAGS)
 100 if test "${commonbfdlib}" = "true"; then
 101   COMMON_SHLIB=yes
 102   # Rebuild the shared library if libiberty or libbfd changes.
 103   SHLIB_DEP="../libiberty/libiberty.a ../bfd/libbfd.a"
 104   BFD_PICLIST=../bfd/piclist
 105 else
 106   COMMON_SHLIB=
 107   SHLIB_DEP=
 108   BFD_PICLIST=
 109 fi
 110 AC_SUBST(COMMON_SHLIB)
 111 AC_SUBST(SHLIB_DEP)
 112 AC_SUBST(BFD_PICLIST)
 113 AC_SUBST(SHLINK)
 114
 115 AC_CHECK_HEADERS(string.h strings.h)
 116
 117 # target-specific stuff:
 118
 119 # Canonicalize the secondary target names.
 120 if test -n "$enable_targets" ; then
 121     for targ in `echo $enable_targets | sed 's/,/ /g'`
 122     do
 123         result=`$ac_config_sub $targ 2>/dev/null`
 124         if test -n "$result" ; then
 125             canon_targets="$canon_targets $result"
 126         else
 127             # Allow targets that config.sub doesn't recognize, like "all".
 128             canon_targets="$canon_targets $targ"
 129         fi
 130     done
 131 fi
 132
 133 all_targets=false
 134 selarchs=
 135 for targ in $target $canon_targets
 136 do
 137     if test "x$targ" = "xall" ; then
 138         all_targets=true
 139     else
 140         . $srcdir/../bfd/config.bfd
 141         selarchs="$selarchs $targ_archs"
 142     fi
 143 done
 144
 145 # We don't do any links based on the target system, just makefile config.
 146
 147 if test x${all_targets} = xfalse ; then
 148
 149     # Target architecture .o files.
 150     ta=
 151
 152     for arch in $selarchs
 153     do
 154         ad=`echo $arch | sed -e s/bfd_//g -e s/_arch//g`
 155         archdefs="$archdefs -DARCH_$ad"
 156         case "$arch" in
 157         bfd_a29k_arch)          ta="$ta a29k-dis.o" ;;
 158         bfd_alliant_arch)       ;;
 159         bfd_alpha_arch)         ta="$ta alpha-dis.o alpha-opc.o" ;;
 160 # start-sanitize-arc
 161         bfd_arc_arch)           ta="$ta arc-dis.o arc-opc.o" ;;
 162 # end-sanitize-arc
 163         bfd_arm_arch)           ta="$ta arm-dis.o" ;;
 164         bfd_convex_arch)        ;;
 165 # start-sanitize-d10v
 166         bfd_d10v_arch)          ta="$ta d10v-dis.o d10v-opc.o" ;;
 167 # end-sanitize-d10v
 168         bfd_h8300_arch)         ta="$ta h8300-dis.o" ;;
 169         bfd_h8500_arch)         ta="$ta h8500-dis.o" ;;
 170         bfd_hppa_arch)          ta="$ta hppa-dis.o" ;;
 171         bfd_i386_arch)          ta="$ta i386-dis.o" ;;
 172         bfd_i860_arch)          ;;
 173         bfd_i960_arch)          ta="$ta i960-dis.o" ;;
 174         bfd_m68k_arch)          ta="$ta m68k-dis.o m68k-opc.o" ;;
 175         bfd_m88k_arch)          ta="$ta m88k-dis.o" ;;
 176         bfd_mips_arch)          ta="$ta mips-dis.o mips-opc.o" ;;
 177         bfd_ns32k_arch)         ta="$ta ns32k-dis.o" ;;
 178         bfd_powerpc_arch)       ta="$ta ppc-dis.o ppc-opc.o" ;;
 179         bfd_pyramid_arch)       ;;
 180         bfd_romp_arch)          ;;
 181         bfd_rs6000_arch)        ta="$ta ppc-dis.o ppc-opc.o" ;;
 182         bfd_sh_arch)            ta="$ta sh-dis.o" ;;
 183         bfd_sparc_arch)         ta="$ta sparc-dis.o sparc-opc.o" ;;
 184         bfd_tahoe_arch)         ;;
 185         bfd_vax_arch)           ;;
 186         bfd_w65_arch)           ta="$ta w65-dis.o" ;;
 187         bfd_we32k_arch)         ;;
 188         bfd_z8k_arch)           ta="$ta z8k-dis.o" ;;
 189
 190         "")                     ;;
 191         *)              AC_MSG_ERROR(*** unknown target architecture $arch) ;;
 192         esac
 193     done
 194
 195     # Weed out duplicate .o files.
 196     f=""
 197     for i in $ta ; do
 198         case " $f " in
 199         *" $i "*) ;;
 200         *) f="$f $i" ;;
 201         esac
 202     done
 203     ta="$f"
 204
 205     # And duplicate -D flags.
 206     f=""
 207     for i in $archdefs ; do
 208         case " $f " in
 209         *" $i "*) ;;
 210         *) f="$f $i" ;;
 211         esac
 212     done
 213     archdefs="$f"
 214
 215     BFD_MACHINES="$ta"
 216
 217 else    # all_targets is true
 218     archdefs=-DARCH_all
 219     BFD_MACHINES='$(ALL_MACHINES)'
 220 fi
 221
 222 AC_SUBST(archdefs)
 223 AC_SUBST(BFD_MACHINES)
 224
 225 AC_OUTPUT(Makefile,
 226 [case x$CONFIG_HEADERS in xconfig.h:config.in) echo > stamp-h ;; esac])