scripts/kconfig/streamline_config.pl

   1 #!/usr/bin/perl -w
   2 #
   3 # Copyright 2005-2009 - Steven Rostedt
   4 # Licensed under the terms of the GNU GPL License version 2
   5 #
   6 #  It's simple enough to figure out how this works.
   7 #  If not, then you can ask me at stripconfig@goodmis.org
   8 #
   9 # What it does?
  10 #
  11 #   If you have installed a Linux kernel from a distribution
  12 #   that turns on way too many modules than you need, and
  13 #   you only want the modules you use, then this program
  14 #   is perfect for you.
  15 #
  16 #   It gives you the ability to turn off all the modules that are
  17 #   not loaded on your system.
  18 #
  19 # Howto:
  20 #
  21 #  1. Boot up the kernel that you want to stream line the config on.
  22 #  2. Change directory to the directory holding the source of the
  23 #       kernel that you just booted.
  24 #  3. Copy the configuraton file to this directory as .config
  25 #  4. Have all your devices that you need modules for connected and
  26 #      operational (make sure that their corresponding modules are loaded)
  27 #  5. Run this script redirecting the output to some other file
  28 #       like config_strip.
  29 #  6. Back up your old config (if you want too).
  30 #  7. copy the config_strip file to .config
  31 #  8. Run "make oldconfig"
  32 #
  33 #  Now your kernel is ready to be built with only the modules that
  34 #  are loaded.
  35 #
  36 # Here's what I did with my Debian distribution.
  37 #
  38 #    cd /usr/src/linux-2.6.10
  39 #    cp /boot/config-2.6.10-1-686-smp .config
  40 #    ~/bin/streamline_config > config_strip
  41 #    mv .config config_sav
  42 #    mv config_strip .config
  43 #    make oldconfig
  44 #
  45 use strict;
  46 use Getopt::Long;
  47
  48 # set the environment variable LOCALMODCONFIG_DEBUG to get
  49 # debug output.
  50 my $debugprint = 0;
  51 $debugprint = 1 if (defined($ENV{LOCALMODCONFIG_DEBUG}));
  52
  53 sub dprint {
  54     return if (!$debugprint);
  55     print STDERR @_;
  56 }
  57
  58 my $config = ".config";
  59
  60 my $uname = `uname -r`;
  61 chomp $uname;
  62
  63 my @searchconfigs = (
  64         {
  65             "file" => ".config",
  66             "exec" => "cat",
  67         },
  68         {
  69             "file" => "/proc/config.gz",
  70             "exec" => "zcat",
  71         },
  72         {
  73             "file" => "/boot/config-$uname",
  74             "exec" => "cat",
  75         },
  76         {
  77             "file" => "/boot/vmlinuz-$uname",
  78             "exec" => "scripts/extract-ikconfig",
  79             "test" => "scripts/extract-ikconfig",
  80         },
  81         {
  82             "file" => "vmlinux",
  83             "exec" => "scripts/extract-ikconfig",
  84             "test" => "scripts/extract-ikconfig",
  85         },
  86         {
  87             "file" => "/lib/modules/$uname/kernel/kernel/configs.ko",
  88             "exec" => "scripts/extract-ikconfig",
  89             "test" => "scripts/extract-ikconfig",
  90         },
  91         {
  92             "file" => "kernel/configs.ko",
  93             "exec" => "scripts/extract-ikconfig",
  94             "test" => "scripts/extract-ikconfig",
  95         },
  96         {
  97             "file" => "kernel/configs.o",
  98             "exec" => "scripts/extract-ikconfig",
  99             "test" => "scripts/extract-ikconfig",
 100         },
 101 );
 102
 103 sub read_config {
 104     foreach my $conf (@searchconfigs) {
 105         my $file = $conf->{"file"};
 106
 107         next if ( ! -f "$file");
 108
 109         if (defined($conf->{"test"})) {
 110             `$conf->{"test"} $conf->{"file"} 2>/dev/null`;
 111             next if ($?);
 112         }
 113
 114         my $exec = $conf->{"exec"};
 115
 116         print STDERR "using config: '$file'\n";
 117
 118         open(my $infile, '-|', "$exec $file") || die "Failed to run $exec $file";
 119         my @x = <$infile>;
 120         close $infile;
 121         return @x;
 122     }
 123     die "No config file found";
 124 }
 125
 126 my @config_file = read_config;
 127
 128 # Parse options
 129 my $localmodconfig = 0;
 130 my $localyesconfig = 0;
 131
 132 GetOptions("localmodconfig" => \$localmodconfig,
 133            "localyesconfig" => \$localyesconfig);
 134
 135 # Get the build source and top level Kconfig file (passed in)
 136 my $ksource = ($ARGV[0] ? $ARGV[0] : '.');
 137 my $kconfig = $ARGV[1];
 138 my $lsmod_file = $ENV{'LSMOD'};
 139
 140 my @makefiles = `find $ksource -name Makefile 2>/dev/null`;
 141 chomp @makefiles;
 142
 143 my %depends;
 144 my %selects;
 145 my %prompts;
 146 my %objects;
 147 my $var;
 148 my $iflevel = 0;
 149 my @ifdeps;
 150
 151 # prevent recursion
 152 my %read_kconfigs;
 153
 154 sub read_kconfig {
 155     my ($kconfig) = @_;
 156
 157     my $state = "NONE";
 158     my $config;
 159     my @kconfigs;
 160
 161     my $cont = 0;
 162     my $line;
 163
 164     my $source = "$ksource/$kconfig";
 165     my $last_source = "";
 166
 167     # Check for any environment variables used
 168     while ($source =~ /\$(\w+)/ && $last_source ne $source) {
 169         my $env = $1;
 170         $last_source = $source;
 171         $source =~ s/\$$env/$ENV{$env}/;
 172     }
 173
 174     open(KIN, "$source") || die "Can't open $kconfig";
 175     while (<KIN>) {
 176         chomp;
 177
 178         # Make sure that lines ending with \ continue
 179         if ($cont) {
 180             $_ = $line . " " . $_;
 181         }
 182
 183         if (s/\\$//) {
 184             $cont = 1;
 185             $line = $_;
 186             next;
 187         }
 188
 189         $cont = 0;
 190
 191         # collect any Kconfig sources
 192         if (/^source\s*"(.*)"/) {
 193             $kconfigs[$#kconfigs+1] = $1;
 194         }
 195
 196         # configs found
 197         if (/^\s*(menu)?config\s+(\S+)\s*$/) {
 198             $state = "NEW";
 199             $config = $2;
 200
 201             # Add depends for 'if' nesting
 202             for (my $i = 0; $i < $iflevel; $i++) {
 203                 if ($i) {
 204                     $depends{$config} .= " " . $ifdeps[$i];
 205                 } else {
 206                     $depends{$config} = $ifdeps[$i];
 207                 }
 208                 $state = "DEP";
 209             }
 210
 211         # collect the depends for the config
 212         } elsif ($state eq "NEW" && /^\s*depends\s+on\s+(.*)$/) {
 213             $state = "DEP";
 214             $depends{$config} = $1;
 215         } elsif ($state eq "DEP" && /^\s*depends\s+on\s+(.*)$/) {
 216             $depends{$config} .= " " . $1;
 217
 218         # Get the configs that select this config
 219         } elsif ($state ne "NONE" && /^\s*select\s+(\S+)/) {
 220             my $conf = $1;
 221             if (defined($selects{$conf})) {
 222                 $selects{$conf} .= " " . $config;
 223             } else {
 224                 $selects{$conf} = $config;
 225             }
 226
 227         # configs without prompts must be selected
 228         } elsif ($state ne "NONE" && /^\s*tristate\s\S/) {
 229             # note if the config has a prompt
 230             $prompts{$config} = 1;
 231
 232         # Check for if statements
 233         } elsif (/^if\s+(.*\S)\s*$/) {
 234             my $deps = $1;
 235             # remove beginning and ending non text
 236             $deps =~ s/^[^a-zA-Z0-9_]*//;
 237             $deps =~ s/[^a-zA-Z0-9_]*$//;
 238
 239             my @deps = split /[^a-zA-Z0-9_]+/, $deps;
 240
 241             $ifdeps[$iflevel++] = join ':', @deps;
 242
 243         } elsif (/^endif/) {
 244
 245             $iflevel-- if ($iflevel);
 246
 247         # stop on "help"
 248         } elsif (/^\s*help\s*$/) {
 249             $state = "NONE";
 250         }
 251     }
 252     close(KIN);
 253
 254     # read in any configs that were found.
 255     foreach $kconfig (@kconfigs) {
 256         if (!defined($read_kconfigs{$kconfig})) {
 257             $read_kconfigs{$kconfig} = 1;
 258             read_kconfig($kconfig);
 259         }
 260     }
 261 }
 262
 263 if ($kconfig) {
 264     read_kconfig($kconfig);
 265 }
 266
 267 # Makefiles can use variables to define their dependencies
 268 sub convert_vars {
 269     my ($line, %vars) = @_;
 270
 271     my $process = "";
 272
 273     while ($line =~ s/^(.*?)(\$\((.*?)\))//) {
 274         my $start = $1;
 275         my $variable = $2;
 276         my $var = $3;
 277
 278         if (defined($vars{$var})) {
 279             $process .= $start . $vars{$var};
 280         } else {
 281             $process .= $start . $variable;
 282         }
 283     }
 284
 285     $process .= $line;
 286
 287     return $process;
 288 }
 289
 290 # Read all Makefiles to map the configs to the objects
 291 foreach my $makefile (@makefiles) {
 292
 293     my $line = "";
 294     my %make_vars;
 295
 296     open(MIN,$makefile) || die "Can't open $makefile";
 297     while (<MIN>) {
 298         # if this line ends with a backslash, continue
 299         chomp;
 300         if (/^(.*)\\$/) {
 301             $line .= $1;
 302             next;
 303         }
 304
 305         $line .= $_;
 306         $_ = $line;
 307         $line = "";
 308
 309         my $objs;
 310
 311         # Convert variables in a line (could define configs)
 312         $_ = convert_vars($_, %make_vars);
 313
 314         # collect objects after obj-$(CONFIG_FOO_BAR)
 315         if (/obj-\$\((CONFIG_[^\)]*)\)\s*[+:]?=\s*(.*)/) {
 316             $var = $1;
 317             $objs = $2;
 318
 319         # check if variables are set
 320         } elsif (/^\s*(\S+)\s*[:]?=\s*(.*\S)/) {
 321             $make_vars{$1} = $2;
 322         }
 323         if (defined($objs)) {
 324             foreach my $obj (split /\s+/,$objs) {
 325                 $obj =~ s/-/_/g;
 326                 if ($obj =~ /(.*)\.o$/) {
 327                     # Objects may be enabled by more than one config.
 328                     # Store configs in an array.
 329                     my @arr;
 330
 331                     if (defined($objects{$1})) {
 332                         @arr = @{$objects{$1}};
 333                     }
 334
 335                     $arr[$#arr+1] = $var;
 336
 337                     # The objects have a hash mapping to a reference
 338                     # of an array of configs.
 339                     $objects{$1} = \@arr;
 340                 }
 341             }
 342         }
 343     }
 344     close(MIN);
 345 }
 346
 347 my %modules;
 348
 349 if (defined($lsmod_file)) {
 350     if ( ! -f $lsmod_file) {
 351         if ( -f $ENV{'objtree'}."/".$lsmod_file) {
 352             $lsmod_file = $ENV{'objtree'}."/".$lsmod_file;
 353         } else {
 354                 die "$lsmod_file not found";
 355         }
 356     }
 357     if ( -x $lsmod_file) {
 358         # the file is executable, run it
 359         open(LIN, "$lsmod_file|");
 360     } else {
 361         # Just read the contents
 362         open(LIN, "$lsmod_file");
 363     }
 364 } else {
 365
 366     # see what modules are loaded on this system
 367     my $lsmod;
 368
 369     foreach my $dir ( ("/sbin", "/bin", "/usr/sbin", "/usr/bin") ) {
 370         if ( -x "$dir/lsmod" ) {
 371             $lsmod = "$dir/lsmod";
 372             last;
 373         }
 374 }
 375     if (!defined($lsmod)) {
 376         # try just the path
 377         $lsmod = "lsmod";
 378     }
 379
 380     open(LIN,"$lsmod|") || die "Can not call lsmod with $lsmod";
 381 }
 382
 383 while (<LIN>) {
 384         next if (/^Module/);  # Skip the first line.
 385         if (/^(\S+)/) {
 386                 $modules{$1} = 1;
 387         }
 388 }
 389 close (LIN);
 390
 391 # add to the configs hash all configs that are needed to enable
 392 # a loaded module. This is a direct obj-${CONFIG_FOO} += bar.o
 393 # where we know we need bar.o so we add FOO to the list.
 394 my %configs;
 395 foreach my $module (keys(%modules)) {
 396     if (defined($objects{$module})) {
 397         my @arr = @{$objects{$module}};
 398         foreach my $conf (@arr) {
 399             $configs{$conf} = $module;
 400             dprint "$conf added by direct ($module)\n";
 401         }
 402     } else {
 403         # Most likely, someone has a custom (binary?) module loaded.
 404         print STDERR "$module config not found!!\n";
 405     }
 406 }
 407
 408 # Read the current config, and see what is enabled. We want to
 409 # ignore configs that we would not enable anyway.
 410
 411 my %orig_configs;
 412 my $valid = "A-Za-z_0-9";
 413
 414 foreach my $line (@config_file) {
 415     $_ = $line;
 416
 417     if (/(CONFIG_[$valid]*)=(m|y)/) {
 418         $orig_configs{$1} = $2;
 419     }
 420 }
 421
 422 my $repeat = 1;
 423
 424 my $depconfig;
 425
 426 #
 427 # Note, we do not care about operands (like: &&, ||, !) we want to add any
 428 # config that is in the depend list of another config. This script does
 429 # not enable configs that are not already enabled. If we come across a
 430 # config A that depends on !B, we can still add B to the list of depends
 431 # to keep on. If A was on in the original config, B would not have been
 432 # and B would not be turned on by this script.
 433 #
 434 sub parse_config_depends
 435 {
 436     my ($p) = @_;
 437
 438     while ($p =~ /[$valid]/) {
 439
 440         if ($p =~ /^[^$valid]*([$valid]+)/) {
 441             my $conf = "CONFIG_" . $1;
 442
 443             $p =~ s/^[^$valid]*[$valid]+//;
 444
 445             # We only need to process if the depend config is a module
 446             if (!defined($orig_configs{$conf}) || !$orig_configs{conf} eq "m") {
 447                 next;
 448             }
 449
 450             if (!defined($configs{$conf})) {
 451                 # We must make sure that this config has its
 452                 # dependencies met.
 453                 $repeat = 1; # do again
 454                 dprint "$conf selected by depend $depconfig\n";
 455                 $configs{$conf} = 1;
 456             }
 457         } else {
 458             die "this should never happen";
 459         }
 460     }
 461 }
 462
 463 # Select is treated a bit differently than depends. We call this
 464 # when a config has no prompt and requires another config to be
 465 # selected. We use to just select all configs that selected this
 466 # config, but found that that can balloon into enabling hundreds
 467 # of configs that we do not care about.
 468 #
 469 # The idea is we look at all the configs that select it. If one
 470 # is already in our list of configs to enable, then there's nothing
 471 # else to do. If there isn't, we pick the first config that was
 472 # enabled in the orignal config and use that.
 473 sub parse_config_selects
 474 {
 475     my ($config, $p) = @_;
 476
 477     my $next_config;
 478
 479     while ($p =~ /[$valid]/) {
 480
 481         if ($p =~ /^[^$valid]*([$valid]+)/) {
 482             my $conf = "CONFIG_" . $1;
 483
 484             $p =~ s/^[^$valid]*[$valid]+//;
 485
 486             # Make sure that this config exists in the current .config file
 487             if (!defined($orig_configs{$conf})) {
 488                 dprint "$conf not set for $config select\n";
 489                 next;
 490             }
 491
 492             # Check if something other than a module selects this config
 493             if (defined($orig_configs{$conf}) && $orig_configs{$conf} ne "m") {
 494                 dprint "$conf (non module) selects config, we are good\n";
 495                 # we are good with this
 496                 return;
 497             }
 498             if (defined($configs{$conf})) {
 499                 dprint "$conf selects $config so we are good\n";
 500                 # A set config selects this config, we are good
 501                 return;
 502             }
 503             # Set this config to be selected
 504             if (!defined($next_config)) {
 505                 $next_config = $conf;
 506             }
 507         } else {
 508             die "this should never happen";
 509         }
 510     }
 511
 512     # If no possible config selected this, then something happened.
 513     if (!defined($next_config)) {
 514         print STDERR "WARNING: $config is required, but nothing in the\n";
 515         print STDERR "  current config selects it.\n";
 516         return;
 517     }
 518
 519     # If we are here, then we found no config that is set and
 520     # selects this config. Repeat.
 521     $repeat = 1;
 522     # Make this config need to be selected
 523     $configs{$next_config} = 1;
 524     dprint "$next_config selected by select $config\n";
 525 }
 526
 527 my %process_selects;
 528
 529 # loop through all configs, select their dependencies.
 530 sub loop_depend {
 531     $repeat = 1;
 532
 533     while ($repeat) {
 534         $repeat = 0;
 535
 536       forloop:
 537         foreach my $config (keys %configs) {
 538
 539             # If this config is not a module, we do not need to process it
 540             if (defined($orig_configs{$config}) && $orig_configs{$config} ne "m") {
 541                 next forloop;
 542             }
 543
 544             $config =~ s/^CONFIG_//;
 545             $depconfig = $config;
 546
 547             if (defined($depends{$config})) {
 548                 # This config has dependencies. Make sure they are also included
 549                 parse_config_depends $depends{$config};
 550             }
 551
 552             # If the config has no prompt, then we need to check if a config
 553             # that is enabled selected it. Or if we need to enable one.
 554             if (!defined($prompts{$config}) && defined($selects{$config})) {
 555                 $process_selects{$config} = 1;
 556             }
 557         }
 558     }
 559 }
 560
 561 sub loop_select {
 562
 563     foreach my $config (keys %process_selects) {
 564         $config =~ s/^CONFIG_//;
 565
 566         dprint "Process select $config\n";
 567
 568         # config has no prompt and must be selected.
 569         parse_config_selects $config, $selects{$config};
 570     }
 571 }
 572
 573 while ($repeat) {
 574     # Get the first set of configs and their dependencies.
 575     loop_depend;
 576
 577     $repeat = 0;
 578
 579     # Now we need to see if we have to check selects;
 580     loop_select;
 581 }
 582
 583 my %setconfigs;
 584
 585 # Finally, read the .config file and turn off any module enabled that
 586 # we could not find a reason to keep enabled.
 587 foreach my $line (@config_file) {
 588     $_ = $line;
 589
 590     if (/CONFIG_IKCONFIG/) {
 591         if (/# CONFIG_IKCONFIG is not set/) {
 592             # enable IKCONFIG at least as a module
 593             print "CONFIG_IKCONFIG=m\n";
 594             # don't ask about PROC
 595             print "# CONFIG_IKCONFIG_PROC is not set\n";
 596         } else {
 597             print;
 598         }
 599         next;
 600     }
 601
 602     if (/^(CONFIG.*)=(m|y)/) {
 603         if (defined($configs{$1})) {
 604             if ($localyesconfig) {
 605                 $setconfigs{$1} = 'y';
 606             } else {
 607                 $setconfigs{$1} = $2;
 608             }
 609         } elsif ($2 eq "m") {
 610             print "# $1 is not set\n";
 611             next;
 612         }
 613     }
 614     print;
 615 }
 616
 617 # Integrity check, make sure all modules that we want enabled do
 618 # indeed have their configs set.
 619 loop:
 620 foreach my $module (keys(%modules)) {
 621     if (defined($objects{$module})) {
 622         my @arr = @{$objects{$module}};
 623         foreach my $conf (@arr) {
 624             if (defined($setconfigs{$conf})) {
 625                 next loop;
 626             }
 627         }
 628         print STDERR "module $module did not have configs";
 629         foreach my $conf (@arr) {
 630             print STDERR " " , $conf;
 631         }
 632         print STDERR "\n";
 633     }
 634 }