scripts/recordmcount.pl

   1 #!/usr/bin/perl -w
   2 # (c) 2008, Steven Rostedt <srostedt@redhat.com>
   3 # Licensed under the terms of the GNU GPL License version 2
   4 #
   5 # recordmcount.pl - makes a section called __mcount_loc that holds
   6 #                   all the offsets to the calls to mcount.
   7 #
   8 #
   9 # What we want to end up with this is that each object file will have a
  10 # section called __mcount_loc that will hold the list of pointers to mcount
  11 # callers. After final linking, the vmlinux will have within .init.data the
  12 # list of all callers to mcount between __start_mcount_loc and __stop_mcount_loc.
  13 # Later on boot up, the kernel will read this list, save the locations and turn
  14 # them into nops. When tracing or profiling is later enabled, these locations
  15 # will then be converted back to pointers to some function.
  16 #
  17 # This is no easy feat. This script is called just after the original
  18 # object is compiled and before it is linked.
  19 #
  20 # When parse this object file using 'objdump', the references to the call
  21 # sites are offsets from the section that the call site is in. Hence, all
  22 # functions in a section that has a call site to mcount, will have the
  23 # offset from the beginning of the section and not the beginning of the
  24 # function.
  25 #
  26 # But where this section will reside finally in vmlinx is undetermined at
  27 # this point. So we can't use this kind of offsets to record the final
  28 # address of this call site.
  29 #
  30 # The trick is to change the call offset referring the start of a section to
  31 # referring a function symbol in this section. During the link step, 'ld' will
  32 # compute the final address according to the information we record.
  33 #
  34 # e.g.
  35 #
  36 #  .section ".sched.text", "ax"
  37 #        [...]
  38 #  func1:
  39 #        [...]
  40 #        call mcount  (offset: 0x10)
  41 #        [...]
  42 #        ret
  43 #  .globl fun2
  44 #  func2:             (offset: 0x20)
  45 #        [...]
  46 #        [...]
  47 #        ret
  48 #  func3:
  49 #        [...]
  50 #        call mcount (offset: 0x30)
  51 #        [...]
  52 #
  53 # Both relocation offsets for the mcounts in the above example will be
  54 # offset from .sched.text. If we choose global symbol func2 as a reference and
  55 # make another file called tmp.s with the new offsets:
  56 #
  57 #  .section __mcount_loc
  58 #  .quad  func2 - 0x10
  59 #  .quad  func2 + 0x10
  60 #
  61 # We can then compile this tmp.s into tmp.o, and link it back to the original
  62 # object.
  63 #
  64 # In our algorithm, we will choose the first global function we meet in this
  65 # section as the reference. But this gets hard if there is no global functions
  66 # in this section. In such a case we have to select a local one. E.g. func1:
  67 #
  68 #  .section ".sched.text", "ax"
  69 #  func1:
  70 #        [...]
  71 #        call mcount  (offset: 0x10)
  72 #        [...]
  73 #        ret
  74 #  func2:
  75 #        [...]
  76 #        call mcount (offset: 0x20)
  77 #        [...]
  78 #  .section "other.section"
  79 #
  80 # If we make the tmp.s the same as above, when we link together with
  81 # the original object, we will end up with two symbols for func1:
  82 # one local, one global.  After final compile, we will end up with
  83 # an undefined reference to func1 or a wrong reference to another global
  84 # func1 in other files.
  85 #
  86 # Since local objects can reference local variables, we need to find
  87 # a way to make tmp.o reference the local objects of the original object
  88 # file after it is linked together. To do this, we convert func1
  89 # into a global symbol before linking tmp.o. Then after we link tmp.o
  90 # we will only have a single symbol for func1 that is global.
  91 # We can convert func1 back into a local symbol and we are done.
  92 #
  93 # Here are the steps we take:
  94 #
  95 # 1) Record all the local and weak symbols by using 'nm'
  96 # 2) Use objdump to find all the call site offsets and sections for
  97 #    mcount.
  98 # 3) Compile the list into its own object.
  99 # 4) Do we have to deal with local functions? If not, go to step 8.
 100 # 5) Make an object that converts these local functions to global symbols
 101 #    with objcopy.
 102 # 6) Link together this new object with the list object.
 103 # 7) Convert the local functions back to local symbols and rename
 104 #    the result as the original object.
 105 # 8) Link the object with the list object.
 106 # 9) Move the result back to the original object.
 107 #
 108
 109 use strict;
 110
 111 my $P = $0;
 112 $P =~ s@.*/@@g;
 113
 114 my $V = '0.1';
 115
 116 if ($#ARGV != 10) {
 117         print "usage: $P arch bits objdump objcopy cc ld nm rm mv is_module inputfile\n";
 118         print "version: $V\n";
 119         exit(1);
 120 }
 121
 122 my ($arch, $bits, $objdump, $objcopy, $cc,
 123     $ld, $nm, $rm, $mv, $is_module, $inputfile) = @ARGV;
 124
 125 # This file refers to mcount and shouldn't be ftraced, so lets' ignore it
 126 if ($inputfile =~ m,kernel/trace/ftrace\.o$,) {
 127     exit(0);
 128 }
 129
 130 # Acceptable sections to record.
 131 my %text_sections = (
 132      ".text" => 1,
 133      ".sched.text" => 1,
 134      ".spinlock.text" => 1,
 135      ".irqentry.text" => 1,
 136      ".text.unlikely" => 1,
 137 );
 138
 139 $objdump = "objdump" if ((length $objdump) == 0);
 140 $objcopy = "objcopy" if ((length $objcopy) == 0);
 141 $cc = "gcc" if ((length $cc) == 0);
 142 $ld = "ld" if ((length $ld) == 0);
 143 $nm = "nm" if ((length $nm) == 0);
 144 $rm = "rm" if ((length $rm) == 0);
 145 $mv = "mv" if ((length $mv) == 0);
 146
 147 #print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
 148 #    "'$nm' '$rm' '$mv' '$inputfile'\n";
 149
 150 my %locals;             # List of local (static) functions
 151 my %weak;               # List of weak functions
 152 my %convert;            # List of local functions used that needs conversion
 153
 154 my $type;
 155 my $local_regex;        # Match a local function (return function)
 156 my $weak_regex;         # Match a weak function (return function)
 157 my $section_regex;      # Find the start of a section
 158 my $function_regex;     # Find the name of a function
 159                         #    (return offset and func name)
 160 my $mcount_regex;       # Find the call site to mcount (return offset)
 161 my $alignment;          # The .align value to use for $mcount_section
 162 my $section_type;       # Section header plus possible alignment command
 163 my $can_use_local = 0;  # If we can use local function references
 164
 165 ##
 166 # check_objcopy - whether objcopy supports --globalize-symbols
 167 #
 168 #  --globalize-symbols came out in 2.17, we must test the version
 169 #  of objcopy, and if it is less than 2.17, then we can not
 170 #  record local functions.
 171 sub check_objcopy
 172 {
 173     open (IN, "$objcopy --version |") or die "error running $objcopy";
 174     while (<IN>) {
 175         if (/objcopy.*\s(\d+)\.(\d+)/) {
 176             $can_use_local = 1 if ($1 > 2 || ($1 == 2 && $2 >= 17));
 177             last;
 178         }
 179     }
 180     close (IN);
 181
 182     if (!$can_use_local) {
 183         print STDERR "WARNING: could not find objcopy version or version " .
 184             "is less than 2.17.\n" .
 185             "\tLocal function references is disabled.\n";
 186     }
 187 }
 188
 189 if ($arch eq "x86") {
 190     if ($bits == 64) {
 191         $arch = "x86_64";
 192     } else {
 193         $arch = "i386";
 194     }
 195 }
 196
 197 #
 198 # We base the defaults off of i386, the other archs may
 199 # feel free to change them in the below if statements.
 200 #
 201 $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
 202 $weak_regex = "^[0-9a-fA-F]+\\s+([wW])\\s+(\\S+)";
 203 $section_regex = "Disassembly of section\\s+(\\S+):";
 204 $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
 205 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount\$";
 206 $section_type = '@progbits';
 207 $type = ".long";
 208
 209 if ($arch eq "x86_64") {
 210     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
 211     $type = ".quad";
 212     $alignment = 8;
 213
 214     # force flags for this arch
 215     $ld .= " -m elf_x86_64";
 216     $objdump .= " -M x86-64";
 217     $objcopy .= " -O elf64-x86-64";
 218     $cc .= " -m64";
 219
 220 } elsif ($arch eq "i386") {
 221     $alignment = 4;
 222
 223     # force flags for this arch
 224     $ld .= " -m elf_i386";
 225     $objdump .= " -M i386";
 226     $objcopy .= " -O elf32-i386";
 227     $cc .= " -m32";
 228
 229 } elsif ($arch eq "s390" && $bits == 32) {
 230     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_32\\s+_mcount\$";
 231     $alignment = 4;
 232     $ld .= " -m elf_s390";
 233     $cc .= " -m31";
 234
 235 } elsif ($arch eq "s390" && $bits == 64) {
 236     $mcount_regex = "^\\s*([0-9a-fA-F]+):\\s*R_390_(PC|PLT)32DBL\\s+_mcount\\+0x2\$";
 237     $alignment = 8;
 238     $type = ".quad";
 239     $ld .= " -m elf64_s390";
 240     $cc .= " -m64";
 241
 242 } elsif ($arch eq "sh") {
 243     $alignment = 2;
 244
 245     # force flags for this arch
 246     $ld .= " -m shlelf_linux";
 247     $objcopy .= " -O elf32-sh-linux";
 248     $cc .= " -m32";
 249
 250 } elsif ($arch eq "powerpc") {
 251     $local_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
 252     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?.*?)>:";
 253     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";
 254
 255     if ($bits == 64) {
 256         $type = ".quad";
 257     }
 258
 259 } elsif ($arch eq "arm") {
 260     $alignment = 2;
 261     $section_type = '%progbits';
 262
 263 } elsif ($arch eq "ia64") {
 264     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 265     $type = "data8";
 266
 267     if ($is_module eq "0") {
 268         $cc .= " -mconstant-gp";
 269     }
 270 } elsif ($arch eq "sparc64") {
 271     # In the objdump output there are giblets like:
 272     # 0000000000000000 <igmp_net_exit-0x18>:
 273     # As there's some data blobs that get emitted into the
 274     # text section before the first instructions and the first
 275     # real symbols.  We don't want to match that, so to combat
 276     # this we use '\w' so we'll match just plain symbol names,
 277     # and not those that also include hex offsets inside of the
 278     # '<>' brackets.  Actually the generic function_regex setting
 279     # could safely use this too.
 280     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\w*?)>:";
 281
 282     # Sparc64 calls '_mcount' instead of plain 'mcount'.
 283     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s_mcount\$";
 284
 285     $alignment = 8;
 286     $type = ".xword";
 287     $ld .= " -m elf64_sparc";
 288     $cc .= " -m64";
 289     $objcopy .= " -O elf64-sparc";
 290 } else {
 291     die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
 292 }
 293
 294 my $text_found = 0;
 295 my $read_function = 0;
 296 my $opened = 0;
 297 my $mcount_section = "__mcount_loc";
 298
 299 my $dirname;
 300 my $filename;
 301 my $prefix;
 302 my $ext;
 303
 304 if ($inputfile =~ m,^(.*)/([^/]*)$,) {
 305     $dirname = $1;
 306     $filename = $2;
 307 } else {
 308     $dirname = ".";
 309     $filename = $inputfile;
 310 }
 311
 312 if ($filename =~ m,^(.*)(\.\S),) {
 313     $prefix = $1;
 314     $ext = $2;
 315 } else {
 316     $prefix = $filename;
 317     $ext = "";
 318 }
 319
 320 my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
 321 my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
 322
 323 check_objcopy();
 324
 325 #
 326 # Step 1: find all the local (static functions) and weak symbols.
 327 #         't' is local, 'w/W' is weak
 328 #
 329 open (IN, "$nm $inputfile|") || die "error running $nm";
 330 while (<IN>) {
 331     if (/$local_regex/) {
 332         $locals{$1} = 1;
 333     } elsif (/$weak_regex/) {
 334         $weak{$2} = $1;
 335     }
 336 }
 337 close(IN);
 338
 339 my @offsets;            # Array of offsets of mcount callers
 340 my $ref_func;           # reference function to use for offsets
 341 my $offset = 0;         # offset of ref_func to section beginning
 342
 343 ##
 344 # update_funcs - print out the current mcount callers
 345 #
 346 #  Go through the list of offsets to callers and write them to
 347 #  the output file in a format that can be read by an assembler.
 348 #
 349 sub update_funcs
 350 {
 351     return unless ($ref_func and @offsets);
 352
 353     # Sanity check on weak function. A weak function may be overwritten by
 354     # another function of the same name, making all these offsets incorrect.
 355     if (defined $weak{$ref_func}) {
 356         die "$inputfile: ERROR: referencing weak function" .
 357             " $ref_func for mcount\n";
 358     }
 359
 360     # is this function static? If so, note this fact.
 361     if (defined $locals{$ref_func}) {
 362
 363         # only use locals if objcopy supports globalize-symbols
 364         if (!$can_use_local) {
 365             return;
 366         }
 367         $convert{$ref_func} = 1;
 368     }
 369
 370     # Loop through all the mcount caller offsets and print a reference
 371     # to the caller based from the ref_func.
 372     for (my $i=0; $i <= $#offsets; $i++) {
 373         if (!$opened) {
 374             open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
 375             $opened = 1;
 376             print FILE "\t.section $mcount_section,\"a\",$section_type\n";
 377             print FILE "\t.align $alignment\n" if (defined($alignment));
 378         }
 379         printf FILE "\t%s %s + %d\n", $type, $ref_func, $offsets[$i] - $offset;
 380     }
 381 }
 382
 383 #
 384 # Step 2: find the sections and mcount call sites
 385 #
 386 open(IN, "$objdump -hdr $inputfile|") || die "error running $objdump";
 387
 388 my $text;
 389
 390
 391 # read headers first
 392 my $read_headers = 1;
 393
 394 while (<IN>) {
 395
 396     if ($read_headers && /$mcount_section/) {
 397         #
 398         # Somehow the make process can execute this script on an
 399         # object twice. If it does, we would duplicate the mcount
 400         # section and it will cause the function tracer self test
 401         # to fail. Check if the mcount section exists, and if it does,
 402         # warn and exit.
 403         #
 404         print STDERR "ERROR: $mcount_section already in $inputfile\n" .
 405             "\tThis may be an indication that your build is corrupted.\n" .
 406             "\tDelete $inputfile and try again. If the same object file\n" .
 407             "\tstill causes an issue, then disable CONFIG_DYNAMIC_FTRACE.\n";
 408         exit(-1);
 409     }
 410
 411     # is it a section?
 412     if (/$section_regex/) {
 413         $read_headers = 0;
 414
 415         # Only record text sections that we know are safe
 416         if (defined($text_sections{$1})) {
 417             $read_function = 1;
 418         } else {
 419             $read_function = 0;
 420         }
 421         # print out any recorded offsets
 422         update_funcs();
 423
 424         # reset all markers and arrays
 425         $text_found = 0;
 426         undef($ref_func);
 427         undef(@offsets);
 428
 429     # section found, now is this a start of a function?
 430     } elsif ($read_function && /$function_regex/) {
 431         $text_found = 1;
 432         $text = $2;
 433
 434         # if this is either a local function or a weak function
 435         # keep looking for functions that are global that
 436         # we can use safely.
 437         if (!defined($locals{$text}) && !defined($weak{$text})) {
 438             $ref_func = $text;
 439             $read_function = 0;
 440             $offset = hex $1;
 441         } else {
 442             # if we already have a function, and this is weak, skip it
 443             if (!defined($ref_func) && !defined($weak{$text}) &&
 444                  # PPC64 can have symbols that start with .L and
 445                  # gcc considers these special. Don't use them!
 446                  $text !~ /^\.L/) {
 447                 $ref_func = $text;
 448                 $offset = hex $1;
 449             }
 450         }
 451     }
 452     # is this a call site to mcount? If so, record it to print later
 453     if ($text_found && /$mcount_regex/) {
 454         $offsets[$#offsets + 1] = hex $1;
 455     }
 456 }
 457
 458 # dump out anymore offsets that may have been found
 459 update_funcs();
 460
 461 # If we did not find any mcount callers, we are done (do nothing).
 462 if (!$opened) {
 463     exit(0);
 464 }
 465
 466 close(FILE);
 467
 468 #
 469 # Step 3: Compile the file that holds the list of call sites to mcount.
 470 #
 471 `$cc -o $mcount_o -c $mcount_s`;
 472
 473 my @converts = keys %convert;
 474
 475 #
 476 # Step 4: Do we have sections that started with local functions?
 477 #
 478 if ($#converts >= 0) {
 479     my $globallist = "";
 480     my $locallist = "";
 481
 482     foreach my $con (@converts) {
 483         $globallist .= " --globalize-symbol $con";
 484         $locallist .= " --localize-symbol $con";
 485     }
 486
 487     my $globalobj = $dirname . "/.tmp_gl_" . $filename;
 488     my $globalmix = $dirname . "/.tmp_mx_" . $filename;
 489
 490     #
 491     # Step 5: set up each local function as a global
 492     #
 493     `$objcopy $globallist $inputfile $globalobj`;
 494
 495     #
 496     # Step 6: Link the global version to our list.
 497     #
 498     `$ld -r $globalobj $mcount_o -o $globalmix`;
 499
 500     #
 501     # Step 7: Convert the local functions back into local symbols
 502     #
 503     `$objcopy $locallist $globalmix $inputfile`;
 504
 505     # Remove the temp files
 506     `$rm $globalobj $globalmix`;
 507
 508 } else {
 509
 510     my $mix = $dirname . "/.tmp_mx_" . $filename;
 511
 512     #
 513     # Step 8: Link the object with our list of call sites object.
 514     #
 515     `$ld -r $inputfile $mcount_o -o $mix`;
 516
 517     #
 518     # Step 9: Move the result back to the original object.
 519     #
 520     `$mv $mix $inputfile`;
 521 }
 522
 523 # Clean up the temp files
 524 `$rm $mcount_o $mcount_s`;
 525
 526 exit(0);