scripts/recordmcount.pl

   1 #!/usr/bin/perl -w
   2 # (c) 2008, Steven Rostedt <srostedt@redhat.com>
   3 # Licensed under the terms of the GNU GPL License version 2
   4 #
   5 # recordmcount.pl - makes a section called __mcount_loc that holds
   6 #                   all the offsets to the calls to mcount.
   7 #
   8 #
   9 # What we want to end up with is a section in vmlinux called
  10 # __mcount_loc that contains a list of pointers to all the
  11 # call sites in the kernel that call mcount. Later on boot up, the kernel
  12 # will read this list, save the locations and turn them into nops.
  13 # When tracing or profiling is later enabled, these locations will then
  14 # be converted back to pointers to some function.
  15 #
  16 # This is no easy feat. This script is called just after the original
  17 # object is compiled and before it is linked.
  18 #
  19 # The references to the call sites are offsets from the section of text
  20 # that the call site is in. Hence, all functions in a section that
  21 # has a call site to mcount, will have the offset from the beginning of
  22 # the section and not the beginning of the function.
  23 #
  24 # The trick is to find a way to record the beginning of the section.
  25 # The way we do this is to look at the first function in the section
  26 # which will also be the location of that section after final link.
  27 # e.g.
  28 #
  29 #  .section ".text.sched"
  30 #  .globl my_func
  31 #  my_func:
  32 #        [...]
  33 #        call mcount  (offset: 0x5)
  34 #        [...]
  35 #        ret
  36 #  other_func:
  37 #        [...]
  38 #        call mcount (offset: 0x1b)
  39 #        [...]
  40 #
  41 # Both relocation offsets for the mcounts in the above example will be
  42 # offset from .text.sched. If we make another file called tmp.s with:
  43 #
  44 #  .section __mcount_loc
  45 #  .quad  my_func + 0x5
  46 #  .quad  my_func + 0x1b
  47 #
  48 # We can then compile this tmp.s into tmp.o, and link it to the original
  49 # object.
  50 #
  51 # But this gets hard if my_func is not globl (a static function).
  52 # In such a case we have:
  53 #
  54 #  .section ".text.sched"
  55 #  my_func:
  56 #        [...]
  57 #        call mcount  (offset: 0x5)
  58 #        [...]
  59 #        ret
  60 #  .globl my_func
  61 #  other_func:
  62 #        [...]
  63 #        call mcount (offset: 0x1b)
  64 #        [...]
  65 #
  66 # If we make the tmp.s the same as above, when we link together with
  67 # the original object, we will end up with two symbols for my_func:
  68 # one local, one global.  After final compile, we will end up with
  69 # an undefined reference to my_func.
  70 #
  71 # Since local objects can reference local variables, we need to find
  72 # a way to make tmp.o reference the local objects of the original object
  73 # file after it is linked together. To do this, we convert the my_func
  74 # into a global symbol before linking tmp.o. Then after we link tmp.o
  75 # we will only have a single symbol for my_func that is global.
  76 # We can convert my_func back into a local symbol and we are done.
  77 #
  78 # Here are the steps we take:
  79 #
  80 # 1) Record all the local symbols by using 'nm'
  81 # 2) Use objdump to find all the call site offsets and sections for
  82 #    mcount.
  83 # 3) Compile the list into its own object.
  84 # 4) Do we have to deal with local functions? If not, go to step 8.
  85 # 5) Make an object that converts these local functions to global symbols
  86 #    with objcopy.
  87 # 6) Link together this new object with the list object.
  88 # 7) Convert the local functions back to local symbols and rename
  89 #    the result as the original object.
  90 #    End.
  91 # 8) Link the object with the list object.
  92 # 9) Move the result back to the original object.
  93 #    End.
  94 #
  95
  96 use strict;
  97
  98 my $P = $0;
  99 $P =~ s@.*/@@g;
 100
 101 my $V = '0.1';
 102
 103 if ($#ARGV < 6) {
 104         print "usage: $P arch objdump objcopy cc ld nm rm mv inputfile\n";
 105         print "version: $V\n";
 106         exit(1);
 107 }
 108
 109 my ($arch, $bits, $objdump, $objcopy, $cc,
 110     $ld, $nm, $rm, $mv, $inputfile) = @ARGV;
 111
 112 # Acceptable sections to record.
 113 my %text_sections = (
 114      ".text" => 1,
 115      ".sched.text" => 1,
 116      ".spinlock.text" => 1,
 117      ".irqentry.text" => 1,
 118 );
 119
 120 $objdump = "objdump" if ((length $objdump) == 0);
 121 $objcopy = "objcopy" if ((length $objcopy) == 0);
 122 $cc = "gcc" if ((length $cc) == 0);
 123 $ld = "ld" if ((length $ld) == 0);
 124 $nm = "nm" if ((length $nm) == 0);
 125 $rm = "rm" if ((length $rm) == 0);
 126 $mv = "mv" if ((length $mv) == 0);
 127
 128 #print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
 129 #    "'$nm' '$rm' '$mv' '$inputfile'\n";
 130
 131 my %locals;             # List of local (static) functions
 132 my %weak;               # List of weak functions
 133 my %convert;            # List of local functions used that needs conversion
 134
 135 my $type;
 136 my $nm_regex;           # Find the local functions (return function)
 137 my $section_regex;      # Find the start of a section
 138 my $function_regex;     # Find the name of a function
 139                         #    (return offset and func name)
 140 my $mcount_regex;       # Find the call site to mcount (return offset)
 141 my $alignment;          # The .align value to use for $mcount_section
 142 my $section_type;       # Section header plus possible alignment command
 143
 144 if ($arch eq "x86") {
 145     if ($bits == 64) {
 146         $arch = "x86_64";
 147     } else {
 148         $arch = "i386";
 149     }
 150 }
 151
 152 #
 153 # We base the defaults off of i386, the other archs may
 154 # feel free to change them in the below if statements.
 155 #
 156 $nm_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\S+)";
 157 $section_regex = "Disassembly of section\\s+(\\S+):";
 158 $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
 159 $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount\$";
 160 $section_type = '@progbits';
 161 $type = ".long";
 162
 163 if ($arch eq "x86_64") {
 164     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
 165     $type = ".quad";
 166     $alignment = 8;
 167
 168     # force flags for this arch
 169     $ld .= " -m elf_x86_64";
 170     $objdump .= " -M x86-64";
 171     $objcopy .= " -O elf64-x86-64";
 172     $cc .= " -m64";
 173
 174 } elsif ($arch eq "i386") {
 175     $alignment = 4;
 176
 177     # force flags for this arch
 178     $ld .= " -m elf_i386";
 179     $objdump .= " -M i386";
 180     $objcopy .= " -O elf32-i386";
 181     $cc .= " -m32";
 182
 183 } elsif ($arch eq "sh") {
 184     $alignment = 2;
 185
 186     # force flags for this arch
 187     $ld .= " -m shlelf_linux";
 188     $objcopy .= " -O elf32-sh-linux";
 189     $cc .= " -m32";
 190
 191 } elsif ($arch eq "powerpc") {
 192     $nm_regex = "^[0-9a-fA-F]+\\s+t\\s+(\\.?\\S+)";
 193     $function_regex = "^([0-9a-fA-F]+)\\s+<(\\.?.*?)>:";
 194     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\s\\.?_mcount\$";
 195
 196     if ($bits == 64) {
 197         $type = ".quad";
 198     }
 199
 200 } elsif ($arch eq "arm") {
 201     $alignment = 2;
 202     $section_type = '%progbits';
 203
 204 } else {
 205     die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
 206 }
 207
 208 my $text_found = 0;
 209 my $read_function = 0;
 210 my $opened = 0;
 211 my $mcount_section = "__mcount_loc";
 212
 213 my $dirname;
 214 my $filename;
 215 my $prefix;
 216 my $ext;
 217
 218 if ($inputfile =~ m,^(.*)/([^/]*)$,) {
 219     $dirname = $1;
 220     $filename = $2;
 221 } else {
 222     $dirname = ".";
 223     $filename = $inputfile;
 224 }
 225
 226 if ($filename =~ m,^(.*)(\.\S),) {
 227     $prefix = $1;
 228     $ext = $2;
 229 } else {
 230     $prefix = $filename;
 231     $ext = "";
 232 }
 233
 234 my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
 235 my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
 236
 237 #
 238 # --globalize-symbols came out in 2.17, we must test the version
 239 # of objcopy, and if it is less than 2.17, then we can not
 240 # record local functions.
 241 my $use_locals = 01;
 242 my $local_warn_once = 0;
 243 my $found_version = 0;
 244
 245 open (IN, "$objcopy --version |") || die "error running $objcopy";
 246 while (<IN>) {
 247     if (/objcopy.*\s(\d+)\.(\d+)/) {
 248         my $major = $1;
 249         my $minor = $2;
 250
 251         $found_version = 1;
 252         if ($major < 2 ||
 253             ($major == 2 && $minor < 17)) {
 254             $use_locals = 0;
 255         }
 256         last;
 257     }
 258 }
 259 close (IN);
 260
 261 if (!$found_version) {
 262     print STDERR "WARNING: could not find objcopy version.\n" .
 263         "\tDisabling local function references.\n";
 264 }
 265
 266
 267 #
 268 # Step 1: find all the local (static functions) and weak symbols.
 269 #        't' is local, 'w/W' is weak (we never use a weak function)
 270 #
 271 open (IN, "$nm $inputfile|") || die "error running $nm";
 272 while (<IN>) {
 273     if (/$nm_regex/) {
 274         $locals{$1} = 1;
 275     } elsif (/^[0-9a-fA-F]+\s+([wW])\s+(\S+)/) {
 276         $weak{$2} = $1;
 277     }
 278 }
 279 close(IN);
 280
 281 my @offsets;            # Array of offsets of mcount callers
 282 my $ref_func;           # reference function to use for offsets
 283 my $offset = 0;         # offset of ref_func to section beginning
 284
 285 ##
 286 # update_funcs - print out the current mcount callers
 287 #
 288 #  Go through the list of offsets to callers and write them to
 289 #  the output file in a format that can be read by an assembler.
 290 #
 291 sub update_funcs
 292 {
 293     return if ($#offsets < 0);
 294
 295     defined($ref_func) || die "No function to reference";
 296
 297     # A section only had a weak function, to represent it.
 298     # Unfortunately, a weak function may be overwritten by another
 299     # function of the same name, making all these offsets incorrect.
 300     # To be safe, we simply print a warning and bail.
 301     if (defined $weak{$ref_func}) {
 302         print STDERR
 303             "$inputfile: WARNING: referencing weak function" .
 304             " $ref_func for mcount\n";
 305         return;
 306     }
 307
 308     # is this function static? If so, note this fact.
 309     if (defined $locals{$ref_func}) {
 310
 311         # only use locals if objcopy supports globalize-symbols
 312         if (!$use_locals) {
 313             return;
 314         }
 315         $convert{$ref_func} = 1;
 316     }
 317
 318     # Loop through all the mcount caller offsets and print a reference
 319     # to the caller based from the ref_func.
 320     for (my $i=0; $i <= $#offsets; $i++) {
 321         if (!$opened) {
 322             open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
 323             $opened = 1;
 324             print FILE "\t.section $mcount_section,\"a\",$section_type\n";
 325             print FILE "\t.align $alignment\n" if (defined($alignment));
 326         }
 327         printf FILE "\t%s %s + %d\n", $type, $ref_func, $offsets[$i] - $offset;
 328     }
 329 }
 330
 331 #
 332 # Step 2: find the sections and mcount call sites
 333 #
 334 open(IN, "$objdump -dr $inputfile|") || die "error running $objdump";
 335
 336 my $text;
 337
 338 while (<IN>) {
 339     # is it a section?
 340     if (/$section_regex/) {
 341
 342         # Only record text sections that we know are safe
 343         if (defined($text_sections{$1})) {
 344             $read_function = 1;
 345         } else {
 346             $read_function = 0;
 347         }
 348         # print out any recorded offsets
 349         update_funcs() if ($text_found);
 350
 351         # reset all markers and arrays
 352         $text_found = 0;
 353         undef($ref_func);
 354         undef(@offsets);
 355
 356     # section found, now is this a start of a function?
 357     } elsif ($read_function && /$function_regex/) {
 358         $text_found = 1;
 359         $offset = hex $1;
 360         $text = $2;
 361
 362         # if this is either a local function or a weak function
 363         # keep looking for functions that are global that
 364         # we can use safely.
 365         if (!defined($locals{$text}) && !defined($weak{$text})) {
 366             $ref_func = $text;
 367             $read_function = 0;
 368         } else {
 369             # if we already have a function, and this is weak, skip it
 370             if (!defined($ref_func) || !defined($weak{$text})) {
 371                 $ref_func = $text;
 372             }
 373         }
 374     }
 375
 376     # is this a call site to mcount? If so, record it to print later
 377     if ($text_found && /$mcount_regex/) {
 378         $offsets[$#offsets + 1] = hex $1;
 379     }
 380 }
 381
 382 # dump out anymore offsets that may have been found
 383 update_funcs() if ($text_found);
 384
 385 # If we did not find any mcount callers, we are done (do nothing).
 386 if (!$opened) {
 387     exit(0);
 388 }
 389
 390 close(FILE);
 391
 392 #
 393 # Step 3: Compile the file that holds the list of call sites to mcount.
 394 #
 395 `$cc -o $mcount_o -c $mcount_s`;
 396
 397 my @converts = keys %convert;
 398
 399 #
 400 # Step 4: Do we have sections that started with local functions?
 401 #
 402 if ($#converts >= 0) {
 403     my $globallist = "";
 404     my $locallist = "";
 405
 406     foreach my $con (@converts) {
 407         $globallist .= " --globalize-symbol $con";
 408         $locallist .= " --localize-symbol $con";
 409     }
 410
 411     my $globalobj = $dirname . "/.tmp_gl_" . $filename;
 412     my $globalmix = $dirname . "/.tmp_mx_" . $filename;
 413
 414     #
 415     # Step 5: set up each local function as a global
 416     #
 417     `$objcopy $globallist $inputfile $globalobj`;
 418
 419     #
 420     # Step 6: Link the global version to our list.
 421     #
 422     `$ld -r $globalobj $mcount_o -o $globalmix`;
 423
 424     #
 425     # Step 7: Convert the local functions back into local symbols
 426     #
 427     `$objcopy $locallist $globalmix $inputfile`;
 428
 429     # Remove the temp files
 430     `$rm $globalobj $globalmix`;
 431
 432 } else {
 433
 434     my $mix = $dirname . "/.tmp_mx_" . $filename;
 435
 436     #
 437     # Step 8: Link the object with our list of call sites object.
 438     #
 439     `$ld -r $inputfile $mcount_o -o $mix`;
 440
 441     #
 442     # Step 9: Move the result back to the original object.
 443     #
 444     `$mv $mix $inputfile`;
 445 }
 446
 447 # Clean up the temp files
 448 `$rm $mcount_o $mcount_s`;
 449
 450 exit(0);