scripts/recordmcount.pl

   1 #!/usr/bin/perl -w
   2 # (c) 2008, Steven Rostedt <srostedt@redhat.com>
   3 # Licensed under the terms of the GNU GPL License version 2
   4 #
   5 # recordmcount.pl - makes a section called __mcount_loc that holds
   6 #                   all the offsets to the calls to mcount.
   7 #
   8 #
   9 # What we want to end up with is a section in vmlinux called
  10 # __mcount_loc that contains a list of pointers to all the
  11 # call sites in the kernel that call mcount. Later on boot up, the kernel
  12 # will read this list, save the locations and turn them into nops.
  13 # When tracing or profiling is later enabled, these locations will then
  14 # be converted back to pointers to some function.
  15 #
  16 # This is no easy feat. This script is called just after the original
  17 # object is compiled and before it is linked.
  18 #
  19 # The references to the call sites are offsets from the section of text
  20 # that the call site is in. Hence, all functions in a section that
  21 # has a call site to mcount, will have the offset from the beginning of
  22 # the section and not the beginning of the function.
  23 #
  24 # The trick is to find a way to record the beginning of the section.
  25 # The way we do this is to look at the first function in the section
  26 # which will also be the location of that section after final link.
  27 # e.g.
  28 #
  29 #  .section ".text.sched"
  30 #  .globl my_func
  31 #  my_func:
  32 #        [...]
  33 #        call mcount  (offset: 0x5)
  34 #        [...]
  35 #        ret
  36 #  other_func:
  37 #        [...]
  38 #        call mcount (offset: 0x1b)
  39 #        [...]
  40 #
  41 # Both relocation offsets for the mcounts in the above example will be
  42 # offset from .text.sched. If we make another file called tmp.s with:
  43 #
  44 #  .section __mcount_loc
  45 #  .quad  my_func + 0x5
  46 #  .quad  my_func + 0x1b
  47 #
  48 # We can then compile this tmp.s into tmp.o, and link it to the original
  49 # object.
  50 #
  51 # But this gets hard if my_func is not globl (a static function).
  52 # In such a case we have:
  53 #
  54 #  .section ".text.sched"
  55 #  my_func:
  56 #        [...]
  57 #        call mcount  (offset: 0x5)
  58 #        [...]
  59 #        ret
  60 #  .globl my_func
  61 #  other_func:
  62 #        [...]
  63 #        call mcount (offset: 0x1b)
  64 #        [...]
  65 #
  66 # If we make the tmp.s the same as above, when we link together with
  67 # the original object, we will end up with two symbols for my_func:
  68 # one local, one global.  After final compile, we will end up with
  69 # an undefined reference to my_func.
  70 #
  71 # Since local objects can reference local variables, we need to find
  72 # a way to make tmp.o reference the local objects of the original object
  73 # file after it is linked together. To do this, we convert the my_func
  74 # into a global symbol before linking tmp.o. Then after we link tmp.o
  75 # we will only have a single symbol for my_func that is global.
  76 # We can convert my_func back into a local symbol and we are done.
  77 #
  78 # Here are the steps we take:
  79 #
  80 # 1) Record all the local symbols by using 'nm'
  81 # 2) Use objdump to find all the call site offsets and sections for
  82 #    mcount.
  83 # 3) Compile the list into its own object.
  84 # 4) Do we have to deal with local functions? If not, go to step 8.
  85 # 5) Make an object that converts these local functions to global symbols
  86 #    with objcopy.
  87 # 6) Link together this new object with the list object.
  88 # 7) Convert the local functions back to local symbols and rename
  89 #    the result as the original object.
  90 #    End.
  91 # 8) Link the object with the list object.
  92 # 9) Move the result back to the original object.
  93 #    End.
  94 #
  95
  96 use strict;
  97
  98 my $P = $0;
  99 $P =~ s@.*/@@g;
 100
 101 my $V = '0.1';
 102
 103 if ($#ARGV < 6) {
 104         print "usage: $P arch objdump objcopy cc ld nm rm mv inputfile\n";
 105         print "version: $V\n";
 106         exit(1);
 107 }
 108
 109 my ($arch, $bits, $objdump, $objcopy, $cc,
 110     $ld, $nm, $rm, $mv, $inputfile) = @ARGV;
 111
 112 # Acceptable sections to record.
 113 my %text_sections = (
 114      ".text" => 1,
 115 );
 116
 117 $objdump = "objdump" if ((length $objdump) == 0);
 118 $objcopy = "objcopy" if ((length $objcopy) == 0);
 119 $cc = "gcc" if ((length $cc) == 0);
 120 $ld = "ld" if ((length $ld) == 0);
 121 $nm = "nm" if ((length $nm) == 0);
 122 $rm = "rm" if ((length $rm) == 0);
 123 $mv = "mv" if ((length $mv) == 0);
 124
 125 #print STDERR "running: $P '$arch' '$objdump' '$objcopy' '$cc' '$ld' " .
 126 #    "'$nm' '$rm' '$mv' '$inputfile'\n";
 127
 128 my %locals;             # List of local (static) functions
 129 my %weak;               # List of weak functions
 130 my %convert;            # List of local functions used that needs conversion
 131
 132 my $type;
 133 my $section_regex;      # Find the start of a section
 134 my $function_regex;     # Find the name of a function
 135                         #    (return offset and func name)
 136 my $mcount_regex;       # Find the call site to mcount (return offset)
 137
 138 if ($arch eq "x86") {
 139     if ($bits == 64) {
 140         $arch = "x86_64";
 141     } else {
 142         $arch = "i386";
 143     }
 144 }
 145
 146 if ($arch eq "x86_64") {
 147     $section_regex = "Disassembly of section\\s+(\\S+):";
 148     $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
 149     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount([+-]0x[0-9a-zA-Z]+)?\$";
 150     $type = ".quad";
 151
 152     # force flags for this arch
 153     $ld .= " -m elf_x86_64";
 154     $objdump .= " -M x86-64";
 155     $objcopy .= " -O elf64-x86-64";
 156     $cc .= " -m64";
 157
 158 } elsif ($arch eq "i386") {
 159     $section_regex = "Disassembly of section\\s+(\\S+):";
 160     $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
 161     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount\$";
 162     $type = ".long";
 163
 164     # force flags for this arch
 165     $ld .= " -m elf_i386";
 166     $objdump .= " -M i386";
 167     $objcopy .= " -O elf32-i386";
 168     $cc .= " -m32";
 169
 170 } elsif ($arch eq "sh") {
 171     $section_regex = "Disassembly of section\\s+(\\S+):";
 172     $function_regex = "^([0-9a-fA-F]+)\\s+<(.*?)>:";
 173     $mcount_regex = "^\\s*([0-9a-fA-F]+):.*\\smcount\$";
 174     $type = ".long";
 175
 176     # force flags for this arch
 177     $ld .= " -m shlelf_linux";
 178     $objcopy .= " -O elf32-sh-linux";
 179     $cc .= " -m32";
 180
 181 } else {
 182     die "Arch $arch is not supported with CONFIG_FTRACE_MCOUNT_RECORD";
 183 }
 184
 185 my $text_found = 0;
 186 my $read_function = 0;
 187 my $opened = 0;
 188 my $mcount_section = "__mcount_loc";
 189
 190 my $dirname;
 191 my $filename;
 192 my $prefix;
 193 my $ext;
 194
 195 if ($inputfile =~ m,^(.*)/([^/]*)$,) {
 196     $dirname = $1;
 197     $filename = $2;
 198 } else {
 199     $dirname = ".";
 200     $filename = $inputfile;
 201 }
 202
 203 if ($filename =~ m,^(.*)(\.\S),) {
 204     $prefix = $1;
 205     $ext = $2;
 206 } else {
 207     $prefix = $filename;
 208     $ext = "";
 209 }
 210
 211 my $mcount_s = $dirname . "/.tmp_mc_" . $prefix . ".s";
 212 my $mcount_o = $dirname . "/.tmp_mc_" . $prefix . ".o";
 213
 214 #
 215 # --globalize-symbols came out in 2.17, we must test the version
 216 # of objcopy, and if it is less than 2.17, then we can not
 217 # record local functions.
 218 my $use_locals = 01;
 219 my $local_warn_once = 0;
 220 my $found_version = 0;
 221
 222 open (IN, "$objcopy --version |") || die "error running $objcopy";
 223 while (<IN>) {
 224     if (/objcopy.*\s(\d+)\.(\d+)/) {
 225         my $major = $1;
 226         my $minor = $2;
 227
 228         $found_version = 1;
 229         if ($major < 2 ||
 230             ($major == 2 && $minor < 17)) {
 231             $use_locals = 0;
 232         }
 233         last;
 234     }
 235 }
 236 close (IN);
 237
 238 if (!$found_version) {
 239     print STDERR "WARNING: could not find objcopy version.\n" .
 240         "\tDisabling local function references.\n";
 241 }
 242
 243
 244 #
 245 # Step 1: find all the local (static functions) and weak symbols.
 246 #        't' is local, 'w/W' is weak (we never use a weak function)
 247 #
 248 open (IN, "$nm $inputfile|") || die "error running $nm";
 249 while (<IN>) {
 250     if (/^[0-9a-fA-F]+\s+t\s+(\S+)/) {
 251         $locals{$1} = 1;
 252     } elsif (/^[0-9a-fA-F]+\s+([wW])\s+(\S+)/) {
 253         $weak{$2} = $1;
 254     }
 255 }
 256 close(IN);
 257
 258 my @offsets;            # Array of offsets of mcount callers
 259 my $ref_func;           # reference function to use for offsets
 260 my $offset = 0;         # offset of ref_func to section beginning
 261
 262 ##
 263 # update_funcs - print out the current mcount callers
 264 #
 265 #  Go through the list of offsets to callers and write them to
 266 #  the output file in a format that can be read by an assembler.
 267 #
 268 sub update_funcs
 269 {
 270     return if ($#offsets < 0);
 271
 272     defined($ref_func) || die "No function to reference";
 273
 274     # A section only had a weak function, to represent it.
 275     # Unfortunately, a weak function may be overwritten by another
 276     # function of the same name, making all these offsets incorrect.
 277     # To be safe, we simply print a warning and bail.
 278     if (defined $weak{$ref_func}) {
 279         print STDERR
 280             "$inputfile: WARNING: referencing weak function" .
 281             " $ref_func for mcount\n";
 282         return;
 283     }
 284
 285     # is this function static? If so, note this fact.
 286     if (defined $locals{$ref_func}) {
 287
 288         # only use locals if objcopy supports globalize-symbols
 289         if (!$use_locals) {
 290             return;
 291         }
 292         $convert{$ref_func} = 1;
 293     }
 294
 295     # Loop through all the mcount caller offsets and print a reference
 296     # to the caller based from the ref_func.
 297     for (my $i=0; $i <= $#offsets; $i++) {
 298         if (!$opened) {
 299             open(FILE, ">$mcount_s") || die "can't create $mcount_s\n";
 300             $opened = 1;
 301             print FILE "\t.section $mcount_section,\"a\",\@progbits\n";
 302         }
 303         printf FILE "\t%s %s + %d\n", $type, $ref_func, $offsets[$i] - $offset;
 304     }
 305 }
 306
 307 #
 308 # Step 2: find the sections and mcount call sites
 309 #
 310 open(IN, "$objdump -dr $inputfile|") || die "error running $objdump";
 311
 312 my $text;
 313
 314 while (<IN>) {
 315     # is it a section?
 316     if (/$section_regex/) {
 317
 318         # Only record text sections that we know are safe
 319         if (defined($text_sections{$1})) {
 320             $read_function = 1;
 321         } else {
 322             $read_function = 0;
 323         }
 324         # print out any recorded offsets
 325         update_funcs() if ($text_found);
 326
 327         # reset all markers and arrays
 328         $text_found = 0;
 329         undef($ref_func);
 330         undef(@offsets);
 331
 332     # section found, now is this a start of a function?
 333     } elsif ($read_function && /$function_regex/) {
 334         $text_found = 1;
 335         $offset = hex $1;
 336         $text = $2;
 337
 338         # if this is either a local function or a weak function
 339         # keep looking for functions that are global that
 340         # we can use safely.
 341         if (!defined($locals{$text}) && !defined($weak{$text})) {
 342             $ref_func = $text;
 343             $read_function = 0;
 344         } else {
 345             # if we already have a function, and this is weak, skip it
 346             if (!defined($ref_func) || !defined($weak{$text})) {
 347                 $ref_func = $text;
 348             }
 349         }
 350     }
 351
 352     # is this a call site to mcount? If so, record it to print later
 353     if ($text_found && /$mcount_regex/) {
 354         $offsets[$#offsets + 1] = hex $1;
 355     }
 356 }
 357
 358 # dump out anymore offsets that may have been found
 359 update_funcs() if ($text_found);
 360
 361 # If we did not find any mcount callers, we are done (do nothing).
 362 if (!$opened) {
 363     exit(0);
 364 }
 365
 366 close(FILE);
 367
 368 #
 369 # Step 3: Compile the file that holds the list of call sites to mcount.
 370 #
 371 `$cc -o $mcount_o -c $mcount_s`;
 372
 373 my @converts = keys %convert;
 374
 375 #
 376 # Step 4: Do we have sections that started with local functions?
 377 #
 378 if ($#converts >= 0) {
 379     my $globallist = "";
 380     my $locallist = "";
 381
 382     foreach my $con (@converts) {
 383         $globallist .= " --globalize-symbol $con";
 384         $locallist .= " --localize-symbol $con";
 385     }
 386
 387     my $globalobj = $dirname . "/.tmp_gl_" . $filename;
 388     my $globalmix = $dirname . "/.tmp_mx_" . $filename;
 389
 390     #
 391     # Step 5: set up each local function as a global
 392     #
 393     `$objcopy $globallist $inputfile $globalobj`;
 394
 395     #
 396     # Step 6: Link the global version to our list.
 397     #
 398     `$ld -r $globalobj $mcount_o -o $globalmix`;
 399
 400     #
 401     # Step 7: Convert the local functions back into local symbols
 402     #
 403     `$objcopy $locallist $globalmix $inputfile`;
 404
 405     # Remove the temp files
 406     `$rm $globalobj $globalmix`;
 407
 408 } else {
 409
 410     my $mix = $dirname . "/.tmp_mx_" . $filename;
 411
 412     #
 413     # Step 8: Link the object with our list of call sites object.
 414     #
 415     `$ld -r $inputfile $mcount_o -o $mix`;
 416
 417     #
 418     # Step 9: Move the result back to the original object.
 419     #
 420     `$mv $mix $inputfile`;
 421 }
 422
 423 # Clean up the temp files
 424 `$rm $mcount_o $mcount_s`;
 425
 426 exit(0);