sim/mips/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.59)dnl
   3 AC_INIT(Makefile.in)
   4 AC_CONFIG_HEADER(config.h:config.in)
   5
   6 sinclude(../common/aclocal.m4)
   7
   8 # Bugs in autoconf 2.59 break the call to SIM_AC_COMMON, hack around
   9 # it by inlining the macro's contents.
  10 sinclude(../common/common.m4)
  11
  12 dnl Options available in this module
  13 SIM_AC_OPTION_INLINE()
  14 SIM_AC_OPTION_ALIGNMENT(NONSTRICT_ALIGNMENT)
  15 SIM_AC_OPTION_HOSTENDIAN
  16 SIM_AC_OPTION_WARNINGS
  17 SIM_AC_OPTION_RESERVED_BITS(1)
  18
  19 # DEPRECATED
  20 #
  21 # Instead of defining a `subtarget' macro, code should be checking
  22 # the value of {STATE,CPU}_ARCHITECTURE to identify the architecture
  23 # in question.
  24 #
  25 case "${target}" in
  26   mips64vr*-*-*)        SIM_SUBTARGET="-DTARGET_ENABLE_FR=1" ;;
  27   mips*tx39*)           SIM_SUBTARGET="-DSUBTARGET_R3900=1";;
  28   mipsisa32*-*-*)       SIM_SUBTARGET="-DTARGET_ENABLE_FR=1";;
  29   mipsisa64*-*-*)       SIM_SUBTARGET="-DTARGET_ENABLE_FR=1";;
  30   *)                    SIM_SUBTARGET="";;
  31 esac
  32 AC_SUBST(SIM_SUBTARGET)
  33
  34
  35
  36 #
  37 # Select the byte order of the target
  38 #
  39 mips_endian=
  40 default_endian=
  41 case "${target}" in
  42   mips64el*-*-*)        mips_endian=LITTLE_ENDIAN ;;
  43   mips64vr*el-*-*)      default_endian=LITTLE_ENDIAN ;;
  44   mips64*-*-*)          default_endian=BIG_ENDIAN ;;
  45   mips16*-*-*)          default_endian=BIG_ENDIAN ;;
  46   mipsisa32*-*-*)       default_endian=BIG_ENDIAN ;;
  47   mipsisa64*-*-*)       default_endian=BIG_ENDIAN ;;
  48   mips*-*-*)            default_endian=BIG_ENDIAN ;;
  49   *)                    default_endian=BIG_ENDIAN ;;
  50 esac
  51 SIM_AC_OPTION_ENDIAN($mips_endian,$default_endian)
  52
  53
  54
  55 #
  56 # Select the bitsize of the target
  57 #
  58 mips_addr_bitsize=
  59 case "${target}" in
  60   mips64*-*-*)          mips_bitsize=64 ; mips_msb=63 ;;
  61   mips16*-*-*)          mips_bitsize=64 ; mips_msb=63 ;;
  62   mipsisa32*-*-*)       mips_bitsize=32 ; mips_msb=31 ;;
  63   mipsisa64*-*-*)       mips_bitsize=64 ; mips_msb=63 ;;
  64   mips*-*-*)            mips_bitsize=32 ; mips_msb=31 ;;
  65   *)                    mips_bitsize=64 ; mips_msb=63 ;;
  66 esac
  67 SIM_AC_OPTION_BITSIZE($mips_bitsize,$mips_msb,$mips_addr_bitsize)
  68
  69
  70
  71 #
  72 # Select the floating hardware support of the target
  73 #
  74 mips_fpu=HARDWARE_FLOATING_POINT
  75 mips_fpu_bitsize=
  76 case "${target}" in
  77   mips*tx39*)           mips_fpu=HARD_FLOATING_POINT
  78                         mips_fpu_bitsize=32
  79                         ;;
  80   mips64*-*-*)          mips_fpu=HARD_FLOATING_POINT ;;
  81   mips16*-*-*)          mips_fpu=HARD_FLOATING_POINT ;;
  82   mipsisa32*-*-*)       mips_fpu=HARD_FLOATING_POINT ; mips_fpu_bitsize=64 ;;
  83   mipsisa64*-*-*)       mips_fpu=HARD_FLOATING_POINT ; mips_fpu_bitsize=64 ;;
  84   mips*-*-*)            mips_fpu=HARD_FLOATING_POINT ; mips_fpu_bitsize=32 ;;
  85   *)                    mips_fpu=HARD_FLOATING_POINT ;;
  86 esac
  87 SIM_AC_OPTION_FLOAT($mips_fpu,$mips_fpu_bitsize)
  88
  89
  90
  91 #
  92 # Select the level of SMP support
  93 #
  94 case "${target}" in
  95   *)                    mips_smp=0 ;;
  96 esac
  97 SIM_AC_OPTION_SMP($mips_smp)
  98
  99
 100
 101 #
 102 # Select the IGEN architecture
 103 #
 104 sim_gen=IGEN
 105 sim_igen_machine="-M mipsIV"
 106 sim_m16_machine="-M mips16,mipsIII"
 107 sim_igen_filter="32,64,f"
 108 sim_m16_filter="16"
 109 sim_mach_default="mips8000"
 110
 111 case "${target}" in
 112   mips*tx39*)           sim_gen=IGEN
 113                         sim_igen_filter="32,f"
 114                         sim_igen_machine="-M r3900"
 115                         ;;
 116   mips64vr43*-*-*)      sim_gen=IGEN
 117                         sim_igen_machine="-M mipsIV"
 118                         sim_mach_default="mips8000"
 119                         ;;
 120   mips64vr5*-*-*)       sim_gen=IGEN
 121                         sim_igen_machine="-M vr5000"
 122                         sim_mach_default="mips5000"
 123                         ;;
 124   mips64vr41*)          sim_gen=M16
 125                         sim_igen_machine="-M vr4100"
 126                         sim_m16_machine="-M vr4100"
 127                         sim_igen_filter="32,64,f"
 128                         sim_m16_filter="16"
 129                         sim_mach_default="mips4100"
 130                         ;;
 131   mips64vr-*-* | mips64vrel-*-*)
 132                         sim_gen=MULTI
 133                         sim_multi_configs="\
 134                           vr4100:mipsIII,mips16,vr4100:32,64:mips4100,mips4111\
 135                           vr4120:mipsIII,mips16,vr4120:32,64:mips4120\
 136                           vr5000:mipsIV:32,64,f:mips4300,mips5000\
 137                           vr5400:mipsIV,vr5400:32,64,f:mips5400\
 138                           vr5500:mipsIV,vr5500:32,64,f:mips5500"
 139                         sim_multi_default=mips5000
 140                         ;;
 141   mips64*-*-*)          sim_igen_filter="32,64,f"
 142                         sim_gen=IGEN
 143                         ;;
 144   mips16*-*-*)          sim_gen=M16
 145                         sim_igen_filter="32,64,f"
 146                         sim_m16_filter="16"
 147                         ;;
 148   mipsisa32r2*-*-*)     sim_gen=IGEN
 149                         sim_igen_machine="-M mips32r2"
 150                         sim_igen_filter="32,f"
 151                         sim_mach_default="mipsisa32r2"
 152                         ;;
 153   mipsisa32*-*-*)       sim_gen=IGEN
 154                         sim_igen_machine="-M mips32"
 155                         sim_igen_filter="32,f"
 156                         sim_mach_default="mipsisa32"
 157                         ;;
 158   mipsisa64r2*-*-*)     sim_gen=IGEN
 159                         sim_igen_machine="-M mips64r2,mips3d"
 160                         sim_igen_filter="32,64,f"
 161                         sim_mach_default="mipsisa64r2"
 162                         ;;
 163   mipsisa64sb1*-*-*)    sim_gen=IGEN
 164                         sim_igen_machine="-M mips64,mips3d,sb1"
 165                         sim_igen_filter="32,64,f"
 166                         sim_mach_default="mips_sb1"
 167                         ;;
 168   mipsisa64*-*-*)       sim_gen=IGEN
 169                         sim_igen_machine="-M mips64,mips3d"
 170                         sim_igen_filter="32,64,f"
 171                         sim_mach_default="mipsisa64"
 172                         ;;
 173   mips*lsi*)            sim_gen=M16
 174                         sim_igen_machine="-M mipsIII,mips16"
 175                         sim_m16_machine="-M mips16,mipsIII"
 176                         sim_igen_filter="32,f"
 177                         sim_m16_filter="16"
 178                         sim_mach_default="mips4000"
 179                         ;;
 180   mips*-*-*)            sim_gen=IGEN
 181                         sim_igen_filter="32,f"
 182                         ;;
 183 esac
 184
 185 # The MULTI generator can combine several simulation engines into one.
 186 # executable.  A configuration which uses the MULTI should set two
 187 # variables: ${sim_multi_configs} and ${sim_multi_default}.
 188 #
 189 # ${sim_multi_configs} is the list of engines to build.  Each
 190 # space-separated entry has the form NAME:MACHINE:FILTER:BFDMACHS,
 191 # where:
 192 #
 193 # - NAME is a C-compatible prefix for the engine,
 194 # - MACHINE is a -M argument,
 195 # - FILTER is a -F argument, and
 196 # - BFDMACHS is a comma-separated list of bfd machines that the
 197 #     simulator can run.
 198 #
 199 # Each entry will have a separate simulation engine whose prefix is
 200 # m32<NAME>.  If the machine list includes "mips16", there will also
 201 # be a mips16 engine, prefix m16<NAME>.  The mips16 engine will be
 202 # generated using the same machine list as the 32-bit version,
 203 # but the filter will be "16" instead of FILTER.
 204 #
 205 # The simulator compares the bfd mach against BFDMACHS to decide
 206 # which engine to use.  Entries in BFDMACHS should be bfd_mach
 207 # values with "bfd_mach_" removed.  ${sim_multi_default} says
 208 # which entry should be the default.
 209 if test ${sim_gen} = MULTI; then
 210
 211   # Simple sanity check.
 212   if test -z "${sim_multi_configs}" || test -z "${sim_multi_default}"; then
 213     AC_MSG_ERROR(Error in configure.in: MULTI simulator not set up correctly)
 214   fi
 215
 216   # Start in a known state.
 217   rm -f multi-include.h multi-run.c
 218   sim_multi_flags=
 219   sim_multi_src=
 220   sim_multi_obj=multi-run.o
 221   sim_multi_igen_configs=
 222   sim_seen_default=no
 223
 224   cat << __EOF__ > multi-run.c
 225 /* Main entry point for MULTI simulators.
 226    Copyright (C) 2003 Free Software Foundation, Inc.
 227
 228    This program is free software; you can redistribute it and/or modify
 229    it under the terms of the GNU General Public License as published by
 230    the Free Software Foundation; either version 2 of the License, or
 231    (at your option) any later version.
 232
 233    This program is distributed in the hope that it will be useful,
 234    but WITHOUT ANY WARRANTY; without even the implied warranty of
 235    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 236    GNU General Public License for more details.
 237
 238    You should have received a copy of the GNU General Public License
 239    along with this program; if not, write to the Free Software
 240    Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
 241
 242    --
 243
 244    This file was generated by sim/mips/configure.  */
 245
 246 #include "sim-main.h"
 247 #include "multi-include.h"
 248
 249 #define SD sd
 250 #define CPU cpu
 251
 252 void
 253 sim_engine_run (SIM_DESC sd,
 254                 int next_cpu_nr,
 255                 int nr_cpus,
 256                 int signal) /* ignore */
 257 {
 258   int mach;
 259
 260   if (STATE_ARCHITECTURE (sd) == NULL)
 261     mach = bfd_mach_${sim_multi_default};
 262   else
 263     mach = STATE_ARCHITECTURE (SD)->mach;
 264
 265   switch (mach)
 266     {
 267 __EOF__
 268
 269   for fc in ${sim_multi_configs}; do
 270
 271     # Split up the entry.  ${c} contains the first three elements.
 272     # Note: outer sqaure brackets are m4 quotes.
 273     c=`echo ${fc} | sed ['s/:[^:]*$//']`
 274     bfdmachs=`echo ${fc} | sed 's/.*://'`
 275     name=`echo ${c} | sed 's/:.*//'`
 276     machine=`echo ${c} | sed 's/.*:\(.*\):.*/\1/'`
 277     filter=`echo ${c} | sed 's/.*://'`
 278
 279     # Build the following lists:
 280     #
 281     #   sim_multi_flags: all -M and -F flags used by the simulator
 282     #   sim_multi_src: all makefile-generated source files
 283     #   sim_multi_obj: the objects for ${sim_multi_src}
 284     #   sim_multi_igen_configs: igen configuration strings.
 285     #
 286     # Each entry in ${sim_multi_igen_configs} is a prefix (m32
 287     # or m16) followed by the NAME, MACHINE and FILTER part of
 288     # the ${sim_multi_configs} entry.
 289     sim_multi_flags="${sim_multi_flags} -F ${filter} -M ${machine}"
 290
 291     # Check whether mips16 handling is needed.
 292     case ${c} in
 293       *:*mips16*:*)
 294         # Run igen twice, once for normal mode and once for mips16.
 295         ws="m32 m16"
 296
 297         # The top-level function for the mips16 simulator is
 298         # in a file m16${name}_run.c, generated by the
 299         # tmp-run-multi Makefile rule.
 300         sim_multi_src="${sim_multi_src} m16${name}_run.c"
 301         sim_multi_obj="${sim_multi_obj} m16${name}_run.o"
 302         sim_multi_flags="${sim_multi_flags} -F 16"
 303         ;;
 304       *)
 305         ws=m32
 306         ;;
 307     esac
 308
 309     # Now add the list of igen-generated files to ${sim_multi_src}
 310     # and ${sim_multi_obj}.
 311     for w in ${ws}; do
 312       for base in engine icache idecode model semantics support; do
 313         sim_multi_src="${sim_multi_src} ${w}${name}_${base}.c"
 314         sim_multi_src="${sim_multi_src} ${w}${name}_${base}.h"
 315         sim_multi_obj="${sim_multi_obj} ${w}${name}_${base}.o"
 316       done
 317       sim_multi_igen_configs="${sim_multi_igen_configs} ${w}${c}"
 318     done
 319
 320     # Add an include for the engine.h file.  This file declares the
 321     # top-level foo_engine_run() function.
 322     echo "#include \"${w}${name}_engine.h\"" >> multi-include.h
 323
 324     # Add case statements for this engine to sim_engine_run().
 325     for mach in `echo ${bfdmachs} | sed 's/,/ /g'`; do
 326       echo "    case bfd_mach_${mach}:" >> multi-run.c
 327       if test ${mach} = ${sim_multi_default}; then
 328         echo "    default:" >> multi-run.c
 329         sim_seen_default=yes
 330       fi
 331     done
 332     echo "      ${w}${name}_engine_run (sd, next_cpu_nr, nr_cpus, signal);" \
 333       >> multi-run.c
 334     echo "      break;" >> multi-run.c
 335   done
 336
 337   # Check whether we added a 'default:' label.
 338   if test ${sim_seen_default} = no; then
 339     AC_MSG_ERROR(Error in configure.in: \${sim_multi_configs} doesn't have an entry for \${sim_multi_default})
 340   fi
 341
 342   cat << __EOF__ >> multi-run.c
 343     }
 344 }
 345
 346 int
 347 mips_mach_multi (SIM_DESC sd)
 348 {
 349   if (STATE_ARCHITECTURE (sd) == NULL)
 350     return bfd_mach_${sim_multi_default};
 351
 352   switch (STATE_ARCHITECTURE (SD)->mach)
 353     {
 354 __EOF__
 355
 356   # Add case statements for this engine to mips_mach_multi().
 357   for fc in ${sim_multi_configs}; do
 358
 359     # Split up the entry.  ${c} contains the first three elements.
 360     # Note: outer sqaure brackets are m4 quotes.
 361     c=`echo ${fc} | sed ['s/:[^:]*$//']`
 362     bfdmachs=`echo ${fc} | sed 's/.*://'`
 363
 364     for mach in `echo ${bfdmachs} | sed 's/,/ /g'`; do
 365       echo "    case bfd_mach_${mach}:" >> multi-run.c
 366     done
 367   done
 368
 369   cat << __EOF__ >> multi-run.c
 370       return (STATE_ARCHITECTURE (SD)->mach);
 371     default:
 372       return bfd_mach_${sim_multi_default};
 373     }
 374 }
 375 __EOF__
 376
 377   SIM_SUBTARGET="$SIM_SUBTARGET -DMIPS_MACH_MULTI"
 378 else
 379   # For clean-extra
 380   sim_multi_src=doesnt-exist.c
 381
 382   if test x"${sim_mach_default}" = x""; then
 383     AC_MSG_ERROR(Error in configure.in: \${sim_mach_default} not defined)
 384   fi
 385   SIM_SUBTARGET="$SIM_SUBTARGET -DMIPS_MACH_DEFAULT=bfd_mach_${sim_mach_default}"
 386 fi
 387 sim_igen_flags="-F ${sim_igen_filter} ${sim_igen_machine} ${sim_igen_smp}"
 388 sim_m16_flags=" -F ${sim_m16_filter}  ${sim_m16_machine}  ${sim_igen_smp}"
 389 AC_SUBST(sim_igen_flags)
 390 AC_SUBST(sim_m16_flags)
 391 AC_SUBST(sim_gen)
 392 AC_SUBST(sim_multi_flags)
 393 AC_SUBST(sim_multi_igen_configs)
 394 AC_SUBST(sim_multi_src)
 395 AC_SUBST(sim_multi_obj)
 396
 397
 398 #
 399 # Add simulated hardware devices
 400 #
 401 hw_enabled=no
 402 case "${target}" in
 403   mips*tx39*)
 404         hw_enabled=yes
 405         hw_extra_devices="tx3904cpu tx3904irc tx3904tmr tx3904sio"
 406         mips_extra_objs="dv-sockser.o"
 407         SIM_SUBTARGET="$SIM_SUBTARGET -DTARGET_TX3904=1"
 408         ;;
 409   *)
 410         mips_extra_objs=""
 411         ;;
 412 esac
 413 SIM_AC_OPTION_HARDWARE($hw_enabled,$hw_devices,$hw_extra_devices)
 414 AC_SUBST(mips_extra_objs)
 415
 416
 417 # Choose simulator engine
 418 case "${target}" in
 419   *)    mips_igen_engine="engine.o"
 420         ;;
 421 esac
 422 AC_SUBST(mips_igen_engine)
 423
 424
 425 AC_PATH_X
 426 mips_extra_libs=""
 427 AC_SUBST(mips_extra_libs)
 428
 429 AC_CHECK_HEADERS(string.h strings.h stdlib.h stdlib.h)
 430 AC_CHECK_LIB(m, fabs)
 431 AC_CHECK_FUNCS(aint anint sqrt)
 432
 433 SIM_AC_OUTPUT