tools/perf/util/parse-events.l

   1
   2 %option reentrant
   3 %option bison-bridge
   4 %option prefix="parse_events_"
   5 %option stack
   6
   7 %{
   8 #include <errno.h>
   9 #include "../perf.h"
  10 #include "parse-events-bison.h"
  11 #include "parse-events.h"
  12
  13 char *parse_events_get_text(yyscan_t yyscanner);
  14 YYSTYPE *parse_events_get_lval(yyscan_t yyscanner);
  15
  16 static int __value(YYSTYPE *yylval, char *str, int base, int token)
  17 {
  18         u64 num;
  19
  20         errno = 0;
  21         num = strtoull(str, NULL, base);
  22         if (errno)
  23                 return PE_ERROR;
  24
  25         yylval->num = num;
  26         return token;
  27 }
  28
  29 static int value(yyscan_t scanner, int base)
  30 {
  31         YYSTYPE *yylval = parse_events_get_lval(scanner);
  32         char *text = parse_events_get_text(scanner);
  33
  34         return __value(yylval, text, base, PE_VALUE);
  35 }
  36
  37 static int raw(yyscan_t scanner)
  38 {
  39         YYSTYPE *yylval = parse_events_get_lval(scanner);
  40         char *text = parse_events_get_text(scanner);
  41
  42         return __value(yylval, text + 1, 16, PE_RAW);
  43 }
  44
  45 static int str(yyscan_t scanner, int token)
  46 {
  47         YYSTYPE *yylval = parse_events_get_lval(scanner);
  48         char *text = parse_events_get_text(scanner);
  49
  50         yylval->str = strdup(text);
  51         return token;
  52 }
  53
  54 static int sym(yyscan_t scanner, int type, int config)
  55 {
  56         YYSTYPE *yylval = parse_events_get_lval(scanner);
  57
  58         yylval->num = (type << 16) + config;
  59         return type == PERF_TYPE_HARDWARE ? PE_VALUE_SYM_HW : PE_VALUE_SYM_SW;
  60 }
  61
  62 static int term(yyscan_t scanner, int type)
  63 {
  64         YYSTYPE *yylval = parse_events_get_lval(scanner);
  65
  66         yylval->num = type;
  67         return PE_TERM;
  68 }
  69
  70 %}
  71
  72 %x mem
  73 %s config
  74 %x event
  75
  76 group           [^,{}/]*[{][^}]*[}][^,{}/]*
  77 event_pmu       [^,{}/]+[/][^/]*[/][^,{}/]*
  78 event           [^,{}/]+
  79
  80 num_dec         [0-9]+
  81 num_hex         0x[a-fA-F0-9]+
  82 num_raw_hex     [a-fA-F0-9]+
  83 name            [a-zA-Z_*?][a-zA-Z0-9_*?]*
  84 name_minus      [a-zA-Z_*?][a-zA-Z0-9\-_*?]*
  85 modifier_event  [ukhpGH]+
  86 modifier_bp     [rwx]{1,3}
  87
  88 %%
  89
  90 %{
  91         {
  92                 int start_token;
  93
  94                 start_token = parse_events_get_extra(yyscanner);
  95
  96                 if (start_token == PE_START_TERMS)
  97                         BEGIN(config);
  98                 else if (start_token == PE_START_EVENTS)
  99                         BEGIN(event);
 100
 101                 if (start_token) {
 102                         parse_events_set_extra(NULL, yyscanner);
 103                         return start_token;
 104                 }
 105          }
 106 %}
 107
 108 <event>{
 109
 110 {group}         {
 111                         BEGIN(INITIAL); yyless(0);
 112                 }
 113
 114 {event_pmu}     |
 115 {event}         {
 116                         str(yyscanner, PE_EVENT_NAME);
 117                         BEGIN(INITIAL); yyless(0);
 118                         return PE_EVENT_NAME;
 119                 }
 120
 121 .               |
 122 <<EOF>>         {
 123                         BEGIN(INITIAL); yyless(0);
 124                 }
 125
 126 }
 127
 128 cpu-cycles|cycles                               { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CPU_CYCLES); }
 129 stalled-cycles-frontend|idle-cycles-frontend    { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_STALLED_CYCLES_FRONTEND); }
 130 stalled-cycles-backend|idle-cycles-backend      { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_STALLED_CYCLES_BACKEND); }
 131 instructions                                    { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_INSTRUCTIONS); }
 132 cache-references                                { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CACHE_REFERENCES); }
 133 cache-misses                                    { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CACHE_MISSES); }
 134 branch-instructions|branches                    { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BRANCH_INSTRUCTIONS); }
 135 branch-misses                                   { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BRANCH_MISSES); }
 136 bus-cycles                                      { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BUS_CYCLES); }
 137 ref-cycles                                      { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_REF_CPU_CYCLES); }
 138 cpu-clock                                       { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CPU_CLOCK); }
 139 task-clock                                      { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_TASK_CLOCK); }
 140 page-faults|faults                              { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS); }
 141 minor-faults                                    { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS_MIN); }
 142 major-faults                                    { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS_MAJ); }
 143 context-switches|cs                             { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CONTEXT_SWITCHES); }
 144 cpu-migrations|migrations                       { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CPU_MIGRATIONS); }
 145 alignment-faults                                { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_ALIGNMENT_FAULTS); }
 146 emulation-faults                                { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_EMULATION_FAULTS); }
 147
 148 L1-dcache|l1-d|l1d|L1-data              |
 149 L1-icache|l1-i|l1i|L1-instruction       |
 150 LLC|L2                                  |
 151 dTLB|d-tlb|Data-TLB                     |
 152 iTLB|i-tlb|Instruction-TLB              |
 153 branch|branches|bpu|btb|bpc             |
 154 node                                    { return str(yyscanner, PE_NAME_CACHE_TYPE); }
 155
 156 load|loads|read                         |
 157 store|stores|write                      |
 158 prefetch|prefetches                     |
 159 speculative-read|speculative-load       |
 160 refs|Reference|ops|access               |
 161 misses|miss                             { return str(yyscanner, PE_NAME_CACHE_OP_RESULT); }
 162
 163 <config>{
 164 config                  { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG); }
 165 config1                 { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG1); }
 166 config2                 { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG2); }
 167 name                    { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_NAME); }
 168 period                  { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_SAMPLE_PERIOD); }
 169 branch_type             { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_BRANCH_SAMPLE_TYPE); }
 170 ,                       { return ','; }
 171 "/"                     { BEGIN(INITIAL); return '/'; }
 172 {name_minus}            { return str(yyscanner, PE_NAME); }
 173 }
 174
 175 mem:                    { BEGIN(mem); return PE_PREFIX_MEM; }
 176 r{num_raw_hex}          { return raw(yyscanner); }
 177 {num_dec}               { return value(yyscanner, 10); }
 178 {num_hex}               { return value(yyscanner, 16); }
 179
 180 {modifier_event}        { return str(yyscanner, PE_MODIFIER_EVENT); }
 181 {name}                  { return str(yyscanner, PE_NAME); }
 182 "/"                     { BEGIN(config); return '/'; }
 183 -                       { return '-'; }
 184 ,                       { BEGIN(event); return ','; }
 185 :                       { return ':'; }
 186 "{"                     { BEGIN(event); return '{'; }
 187 "}"                     { return '}'; }
 188 =                       { return '='; }
 189 \n                      { }
 190
 191 <mem>{
 192 {modifier_bp}           { return str(yyscanner, PE_MODIFIER_BP); }
 193 :                       { return ':'; }
 194 {num_dec}               { return value(yyscanner, 10); }
 195 {num_hex}               { return value(yyscanner, 16); }
 196         /*
 197          * We need to separate 'mem:' scanner part, in order to get specific
 198          * modifier bits parsed out. Otherwise we would need to handle PE_NAME
 199          * and we'd need to parse it manually. During the escape from <mem>
 200          * state we need to put the escaping char back, so we dont miss it.
 201          */
 202 .                       { unput(*yytext); BEGIN(INITIAL); }
 203         /*
 204          * We destroy the scanner after reaching EOF,
 205          * but anyway just to be sure get back to INIT state.
 206          */
 207 <<EOF>>                 { BEGIN(INITIAL); }
 208 }
 209
 210 %%
 211
 212 int parse_events_wrap(void *scanner __maybe_unused)
 213 {
 214         return 1;
 215 }